🚀 go-pugleaf

Sharon--

You're not being a pain at all!

Here's an updated version of the earlier script (run this one from the InDesign Scripts palette):



Dim myInDesign 
Rem Enter the number or rows and columns you want. If you're adding 
Rem a user interface to this script, you can get these values from 
Rem a pair of text fields. 
myNumberOfRows = 4 
myNumberOfColumns = 3 
Rem If you want to remove any empty frames, set myRemoveEmptyFrames to true. 
myRemoveEmptyFrames = True 
Rem Enter the path to the folder containing the images you want to place. 
myFolderName = "d:\myFilesToPlace" 
myFramesPerPage = myNumberOfRows * myNumberOfColumns 
Set myInDesign = CreateObject("InDesign.Application.CS") 
Set myDocument = myInDesign.Documents.Add 
Set myDocumentPreferences = myDocument.DocumentPreferences 
Set myFileSystemObject = CreateObject("Scripting.FileSystemObject") 
Rem Fill in the path to the folder containing the files you want to place. 
Rem If you're add a user interface to this script, you can use a DirListBox 
Rem to set the folder location. 
Set myFolder = myFileSystemObject.GetFolder(myFolderName) 
myNumberOfFrames = myFolder.Files.Count 
myNumberOfPages = Round(myNumberOfFrames / myFramesPerPage) 
If (myNumberOfPages * myFramesPerPage) < myNumberOfFrames Then myNumberOfPages = myNumberOfPages + 1 
myDocumentPreferences.PagesPerDocument = CInt(myNumberOfPages) 
myDocumentPreferences.FacingPages = False 
Set myPage = myDocument.Pages.Item(1) 
Set myMarginPreferences = myPage.MarginPreferences 
myLeftMargin = myMarginPreferences.Left 
myTopMargin = myMarginPreferences.Top 
myRightMargin = myMarginPreferences.Right 
myBottomMargin = myMarginPreferences.Bottom 
myLiveWidth = myDocumentPreferences.PageWidth - (myLeftMargin + myRightMargin) 
myLiveHeight = myDocumentPreferences.PageHeight - (myTopMargin + myBottomMargin) 
myFrameWidth = myLiveWidth / myNumberOfColumns 
myFrameHeight = myLiveHeight / myNumberOfRows 
Set myPages = myDocument.Pages 
Rem Construct the frames in reverse order. Don't laugh--this will 
Rem save us time later (when we place the graphics). 
For myCounter = myDocument.Pages.Count To 1 Step -1 
    Set myPage = myPages.Item(CInt(myCounter)) 
    For myRowCounter = myNumberOfRows To 1 Step -1 
        myY1 = myTopMargin + (myFrameHeight * (myRowCounter - 1)) 
        myY2 = myTopMargin + (myFrameHeight * myRowCounter) 
        For myColumnCounter = myNumberOfColumns To 1 Step -1 
            myX1 = myLeftMargin + (myFrameWidth * (myColumnCounter - 1)) 
            myX2 = myLeftMargin + (myFrameWidth * myColumnCounter) 
            Set myRectangle = myPage.Rectangles.Add 
            myRectangle.GeometricBounds = Array(myY1, myX1, myY2, myX2) 
        Next 
    Next 
Next 
Rem Because we constructed the frames in reverse order, rectangle 1 
Rem is the first rectangle on page 1, so we can simply iterate through 
Rem the rectangles, placing a file in each one in turn. 
myCounter = 1 
Set myFiles = myFolder.Files 
For Each File In myFiles 
    myPath = File.Path 
    myDocument.PageItems.Item(myCounter).Place myPath 
    myDocument.PageItems.Item(myCounter).Fit idFitOptions.idProportionally 
    myDocument.PageItems.Item(myCounter).Fit idFitOptions.idCenterContent 
    myCounter = myCounter + 1 
Next 
If myRemoveEmptyFrames = True Then 
    For Each Rectangle In myDocument.Rectangles 
        If Rectangle.ContentType = idContentType.idUnassigned Then 
            Rectangle.Delete 
        End If 
    Next 
End If

I'll try to post a fancier one (i.e., one with a user interface) later.

Thanks,

Ole