🚀 go-pugleaf

That's kind of strange, you don't usually think so much in terms of which record number it is, but rather flow sequentially and make decisions based on field name and context in the flow. Anyway, as a general example, here's some code that puts even records into text frames 1 and 2, and odd records into text frames 3 and 4. Not that someone would really do this... 

Option Compare Database 

Public Function SetupPage(oPage, iPage) 
    Rem Make the X textboxes on a new page 
    Rem Takes the page object and the page number 
    Rem DOESNT thread the frames... 
    Set oDocument = oPage.Parent.Parent 
    iColumns = oPage.MarginPreferences.ColumnCount 
    dPageWidth = oDocument.DocumentPreferences.PageWidth 
    dPageHeight = oDocument.DocumentPreferences.PageHeight 
    dGutter = oPage.MarginPreferences.ColumnGutter 
    If iPage Mod 2 = 0 Then 
        dMarginRight = oPage.MarginPreferences.MarginLeft 
        dMarginLeft = oPage.MarginPreferences.MarginRight 
    Else 
        dMarginRight = oPage.MarginPreferences.MarginRight 
        dMarginLeft = oPage.MarginPreferences.MarginLeft 
    End If 
    dMarginTop = oPage.MarginPreferences.MarginTop 
    dMarginBottom = oPage.MarginPreferences.MarginBottom 
    dColumnWidth = (dPageWidth - (dMarginRight + dMarginLeft) _ 
        - (dGutter * (iColumns - 1))) / iColumns 
    dY1 = dMarginTop 
    dY2 = dPageHeight - dMarginBottom 
    For i = 1 To iColumns 
        dOffset = (i - 1) * (dColumnWidth + dGutter) 
        dX1 = dMarginLeft + dOffset 
        dX2 = dX1 + dColumnWidth 
        Set oTextFrame = oPage.TextFrames.Add 
        oTextFrame.GeometricBounds = Array(dY1, dX1, dY2, dX2) 
        oTextFrame.Label = "TF_" & iPage & "_" & i 
        If i = 1 Then 
            Set SetupPage = oTextFrame 
        End If 
    Next 
End Function 
Public Function Output() 
    Dim db As DAO.Database 
    Dim rs As DAO.Recordset 
    Set db = CurrentDb 
    Set rs = db.OpenRecordset("tblMyTable", dbOpenDynaset) 
    Dim oInDesign As InDesign.Application 
    Set oInDesign = CreateObject("InDesign.Application.2.0") 
    Set oDocument = oInDesign.Documents.Add 
    Set oPage = oDocument.Pages.Item(1) 
    Set oPrevTextFrame = Nothing 
    SetupPage oPage, 1 
    iPage = 1 
    iCounter = 0 
    Do While Not rs.EOF 
        iCounter = iCounter + 1 
        If Not iCounter Mod 2 = 0 Then 
            ' Every other record will be in different 
            ' text frames... 
            sBuf = rs!myField1 
            Rem this one goes in the first frame 
            sFrame = "TF_" & iPage & "_1" 
            Set oTextFrame = oPage.TextFrames.Item(sFrame) 
            oTextFrame.InsertionPoints.Item(-1).TextContents = sBuf _ 
                & vbCr 
            sBuf = rs!myField2 
            Rem this one goes in the second frame 
            sFrame = "TF_" & iPage & "_2" 
            Set oTextFrame = oPage.TextFrames.Item(sFrame) 
            oTextFrame.InsertionPoints.Item(-1).TextContents = sBuf _ 
                & vbCr 
        Else 
            sBuf = rs!myField1 
            Rem this one goes in the third frame 
            sFrame = "TF_" & iPage & "_3" 
            Set oTextFrame = oPage.TextFrames.Item(sFrame) 
            oTextFrame.InsertionPoints.Item(-1).TextContents = sBuf _ 
                & vbCr 
            sBuf = rs!myField2 
            Rem this one goes in the fourth frame 
            sFrame = "TF_" & iPage & "_4" 
            Set oTextFrame = oPage.TextFrames.Item(sFrame) 
            oTextFrame.InsertionPoints.Item(-1).TextContents = sBuf _ 
                & vbCr 
        End If 
        Rem probably add pages based on some condition here 
        rs.MoveNext 
    Loop 
    rs.Close 
    Set rs = Nothing 
End Function