🚀 go-pugleaf

tm@netcom.com (Toshiyasu Morita) writes:

>I'm looking for a fast min() and max() algorithm, preferably without branching.

----------------------------------------------------------------------
; ax := unsigned-min(ax,dx)
;
	sub	ax,dx
	sbb	cx,cx
	and	ax,cx
	add	ax,dx
----------------------------------------------------------------------
; ax := unsigned-max(ax,dx)
;
	sub	dx,ax
	add	ax,dx
	sbb	cx,cx
	and	cx,dx
	sub	ax,cx
----------------------------------------------------------------------

The sequences are optimal for the 386 and 486 in 16-bit segments.
In 32-bit segments use 32 bit registers.

The best signed versions I can think of is by adding 8000h to the
operands, using the unsigned versions, and subtracting 8000h from the 
results:

----------------------------------------------------------------------
; ax := signed-min(ax,dx)
;
	xor	ah,80h
	xor	dh,80h
	sub	ax,dx
	sbb	cx,cx
	and	ax,cx
	add	ax,dx
	xor	ah,80h
----------------------------------------------------------------------
; ax := signed-max(ax,dx)
;
	xor	ah,80h
	xor	dh,80h
	sub	dx,ax
	add	ax,dx
	sbb	cx,cx
	and	cx,dx
	sub	ax,cx
	xor	ah,80h
----------------------------------------------------------------------



Morten Welinder
terra@diku.dk


-- 
------------------------------------------------------------------------
Visit the lyrics archive at ftp.cs.uwp (mirrored to nic.funet.fi, a site
in Finland). All kinds of lyrics available -- upload "yours" and join.
------------------------------------------Morten Welinder, terra@diku.dk