🚀 go-pugleaf

> >
> >
> > Wat ik vroeger ooit eens gedaan heb bij Brinkster is via een
VB-applicatie
> > de header opvragen van een ASP-pagina met parameters.
> > Dan ging ik de info uit de databank gaan toevoegen aan de header van de
> > pagina en kon ik door het parsen van deze response de velden in het
> > programma vullen.
> >
>
> Kan je zo ook de velden van een formulier gaan vullen? Heb je daar enkele
> voorbeelden voor?
>
>

Je hebt geluk, ik heb de code hier nog staan, want 't is al van enkele
jaartjes geleden...

Ik zal je de code geven van de login-check, daar worden parameters
meegegeven, deze kan je dan verifi�ren of in de databank bewaren.


------------------ VB APPLICATIE ------------------

Private Sub cmdLogin_Click()
    cmdLogin.Enabled = False
    SaveSetting Appname, Section, "Login", txtNaam
    SaveSetting Appname, Section, "Code", txtCode
    Winsock1.Connect Brinksterserver, Brinksterport
End Sub

Private Sub Winsock1_Connect()
    Dim sHTTP As String
    sHTTP = "HEAD " & BrinksterDir & "/Login.asp?N=" & txtNaam & "&P=" &
txtPaswoord & "&C=" & txtCode & " HTTP/1.1" & vbCrLf
    sHTTP = sHTTP & "Host: " & Brinksterserver & vbCrLf
    sHTTP = sHTTP & "Accept: */*" & vbCrLf
    sHTTP = sHTTP & "Connection: close" & vbCrLf
    Winsock1.SendData sHTTP & vbCrLf
End Sub

Private Sub Winsock1_DataArrival(ByVal bytesTotal As Long)
Dim sReturn As String
Dim sID As String
Dim pos As Long
Dim pos2 As Long
    Winsock1.GetData sReturn, vbString
    Winsock1.Close
    If InStr(1, sReturn, "Login: OK", vbTextCompare) > 0 Then
        NaamGebruiker = txtNaam
        pos = InStr(1, sReturn, "UserID: ", vbTextCompare)
        pos2 = InStr(pos, sReturn, vbCrLf)
        sID = mID(sReturn, pos + 7, pos2 - pos - 7)
        IDGebruiker = CLng(sID)
        frmMain.Show
        Unload Me
    Else
        GeefMelding OngeldigeLogin
        cmdLogin.Enabled = True
        If txtNaam <> "" Then
            txtPaswoord.SetFocus
        End If
    End If
End Sub


------------------ LOGIN ASP PAGINA ------------------

<%
Option explicit
Response.Expires = -1000
Response.Buffer = True

Dim CON, RS, SQL
Dim LoginOK

Const BrinksterDir = "<Uw Brinkster Account Name>"


Set CON = Server.CreateObject("ADODB.Connection")
CON.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" &
server.MapPath(BrinksterDir & "/db") & "\<Naam Van Uw Databank>.mdb"
Set RS = Server.CreateObject("ADODB.RecordSet")

function CleanSQL(s)
 CleanSQL = replace(s, "'", "''")
end function

LoginOK = False

SQL = "Select ID_Gebruiker, Paswoord, Code, LastLogin, Logins from
Gebruikers where login = '" & cleansql(Request.QueryString("N")) & "'"
RS.Open SQL, CON, 1, 3
If RS.EOF Then
 LoginOK = False
Else
 If RS("Paswoord") = Request.QueryString("P") And RS("Code") =
Request.QueryString("C") Then
  RS("Lastlogin") = cstr(Date)
  RS("Logins") = RS("Logins") + 1
  RS.Update
  LoginOK = True
 Else
  LoginOK = False
 End If
End If


If Not LoginOK Then
 Response.AddHeader "Login", "NOK"
Else
 Response.AddHeader "Login", "OK"
 Response.AddHeader "UserID", RS("ID_Gebruiker")
End If

RS.Close
CON.Close
Set RS = Nothing
Set CON = Nothing
%>

------------------ EINDE ------------------


Ik hoop dat je iets aan deze code hebt...


mvg