🚀 go-pugleaf

On Fri, 17 Jul 1992 14:47:01 MDT <ROBR%NAIT.AB.CA@VM.UCS.UALBERTA.CA> said:
>Hello,
>
>      I am looking for some macros to enhance my use of XEDIT. I have
some deleted
>     And any other nifty ones I haven't thought about.
Here is an  overlay macro, use it  by specifying a block move  or copy in
the prefix area and then Onn in the prefix area of the target.  nn is the
number of  columns to shift  the block right.   The block is  shifted and
overlayed starting at the target.
/*******************************************************************/
/* O XEDIT Imitate SPF editor overlay                              */
/* Copy support added by Paul Pratte                               */
/*      Original by Roger Bagnall                                  */
/*                                                                 */
/*******************************************************************/
arg . . ovly_line column .

'COMMAND EXTRACT /LINE/'               /* store line to restore screen */
current_line = line.1

'COMMAND LOCATE :'ovly_line                         /* pending message */
'COMMAND SET PENDING ON O'column
'COMMAND LOCATE :'current_line

'COMMAND EXTRACT /PENDING M :1 */'
If pending.0 ^= 0
then do
    'COMMAND LOCATE :'pending.1
    if pending.5 = '' | pending.5 = ' ' then howmuch=1
    else howmuch=pending.5
    'COMMAND MERGE 'howmuch ':'ovly_line column
    If rc ^= 0 then exit
    'COMMAND EXTRACT /PENDING O :1 */'
    'COMMAND LOCATE :'pending.1
    'COMMAND SET PENDING OFF'
    'COMMAND LOCATE :'current_line
    exit
end

'COMMAND EXTRACT /PENDING BLOCK MM :1 */'
If pending.0 ^= 0
then do
      merge_top = pending.1

     'COMMAND EXTRACT /PENDING BLOCK MM :'merge_top + 1 '* /'
     If pending.0 = 0  then exit
     merge_end = pending.1 + 1

     'COMMAND LOCATE :'merge_top
     'COMMAND MERGE :'merge_end ':'ovly_line column
     If rc ^= 0 then exit
     'COMMAND EXTRACT /PENDING O :1 */'
     'COMMAND LOCATE :'pending.1
     'COMMAND SET PENDING OFF'
     'COMMAND LOCATE :'current_line
     exit
end
'COMMAND EXTRACT /PENDING C :1 */'
If pending.0 ^= 0
then do
    if pending.5 = '' | pending.5 = ' ' then howmuch=1
    else howmuch=pending.5
    'COMMAND LOCATE :'pending.1
    'COMMAND PUT 'howmuch
    'COMMAND LOCATE :'pending.1
    'COMMAND MERGE' howmuch ':'ovly_line column
    If rc ^= 0 then exit
    if pending.1-1 < 1 then 'COMMAND TOP'
    else 'COMMAND LOCATE :'pending.1 - 1
    'COMMAND GET '
    'COMMAND EXTRACT /PENDING O :1 */'
    'COMMAND LOCATE :'pending.1
    'COMMAND SET PENDING OFF'
    'COMMAND LOCATE :'current_line
    exit
end
'COMMAND EXTRACT /PENDING BLOCK CC :1 */'
If pending.0 ^= 0
then do
      merge_top = pending.1
     'COMMAND EXTRACT /PENDING BLOCK CC :'merge_top + 1 '* /'
     If pending.0 = 0  then exit
     merge_end = pending.1 + 1
     'COMMAND LOCATE :'merge_top
     'COMMAND PUT  'abs(merge_top-merge_end)
     'COMMAND LOCATE :'merge_top
     'COMMAND MERGE :'merge_end ':'ovly_line column
     If rc ^= 0 then exit
     'COMMAND LOCATE :'merge_top-1
     'COMMAND GET  '
     'COMMAND EXTRACT /PENDING O :1 */'
     'COMMAND LOCATE :'pending.1
     'COMMAND SET PENDING OFF'
     'COMMAND LOCATE :'current_line
     exit
end
exit