🚀 go-pugleaf

>Date:         Wed, 29 Apr 1992 14:27:34 EDT
>Reply-To:     VM System Editor List <XEDIT-L@uga.cc.uga.edu>
>From:         laszlo grunfeld <LAZBM%CUNYVM.BITNET@uga.cc.uga.edu>
>
>I have a file with names like this
>
>JOHN DOE
>JANE DOE
>...
>I'd like to convert them to look like this
>John Doe
>Jane Doe
>...
>Does anyone have a macro to do this?
>
>Thanks
>
>Laszlo Grunfeld


The following macro will convert all the lines in a file and will leave all
column alignments unchanged.


/* FIXNAMES XEDIT MACRO */

lcase = 'abcdefghijklmnopqrstuvwxyz'
ucase = 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'

'COMMAND :1'

do forever
   'COMMAND EXTRACT /CURLINE/'
   cl = curline.3
   nl = ''
   $ = 1
   ld = 1
   do forever
      wi = wordindex(cl,$)
      if wi=0 then leave
      if wi^=ld then do
         blanks = copies(' ',wi-ld)
         nl = nl || blanks
         end
      w = word(cl,$)
      wl = length(w)
      w = translate(w,lcase,ucase)
      w = translate(left(w,1)) || substr(w,2)
      nl = nl || w
      ld = wi + wl
      $ = $ + 1
      end
   'COMMAND CLOCATE :1'
   'COMMAND CREPLACE' nl
   'COMMAND NEXT'
   if rc^=0 then leave
   end

exit