🚀 go-pugleaf

Hello Frans,

below is unit i found some time ago. It executes external-commands and waits
for them to finish.

Regards, Erik


//**************************************************************************
*********************
unit execwait;

interface

uses
  Windows, Forms, ShellAPI; // Include SHELLAPI in this "uses" clause

function ExecAppWait(AppName, Params: string): Boolean ;

implementation

{
  Execute an external application APPNAME.
  Pass optional parameters in PARAMS, separated by spaces.
  Wait for completion of the application
  Returns FALSE if application failed.
}
function ExecAppWait(AppName, Params: string): Boolean;
var
  // Structure containing and receiving info about application to start
  ShellExInfo: TShellExecuteInfo;
begin
  FillChar(ShellExInfo, SizeOf(ShellExInfo), 0);

  with ShellExInfo do begin
    cbSize       := SizeOf(ShellExInfo);
    fMask        := see_Mask_NoCloseProcess;
    Wnd          := Application.Handle;
    lpFile       := PChar(AppName);
    lpParameters := PChar(Params);
    nShow        := sw_ShowNormal;
  end;

  Result := ShellExecuteEx(@ShellExInfo);

  if Result then begin

    while WaitForSingleObject(ShellExInfo.HProcess, 100) = WAIT_TIMEOUT do
    begin
      Application.ProcessMessages;
      if Application.Terminated then Break;
    end;

  end;

end;

end.
//**************************************************************************
*********************


"Frans van Zyl" <fransv@praxima.co.za> wrote in message
news:41a4b767@newsgroups.borland.com...
> Hi,
>
> I need to pass a command to DOS, but I cannot find the way to do it.
>
> I am currently using Delphi 5
>
> Regards
> - Frans van Zyl  (fransv@praxima.co.za)
>
>