🚀 go-pugleaf

Hi

Hope this example helps... Easier then explaining!!  B)

Adrian

----

Uses
  WinSpool;

Type
  TArrayPORT_INFO_1 = Array[0..0] Of PORT_INFO_1;
  PArrayPORT_INFO_1 = ^TArrayPORT_INFO_1;

procedure LPT1Check();
Var
  apiBuffer:    PArrayPORT_INFO_1;
  lwBufferSize: LongWord;
  lwPortCount:  LongWord;
  lwIndex:      LongWord;
  sMessage:     String;
begin
  // Find required size of the buffer
  EnumPorts(Nil, 1, Nil, 0, lwBufferSize, lwPortCount);

  // Alloc and fill buffer
  apiBuffer := AllocMem(lwBufferSize);
  EnumPorts(Nil, 1, apiBuffer, lwBufferSize, lwBufferSize, lwPortCount);

  // Search returned buffer
  // Using word so must check for 0 as 0 - 1 = 4294967295  not -1!
  If lwPortCount = 0 Then
    sMessage := 'No ports installed on this system'
  Else
  Begin
    sMessage := 'LPT1: not found on this system';

    For lwIndex := 0 To lwPortCount - 1 Do
    Begin
      If UpperCase(apiBuffer[lwIndex].pName) = 'LPT1:' Then
      Begin
        sMessage := 'LPT1: exists';
        Break;
      End;    // If name
    End;    // For lwIndex
  End;    // If lwPortCount

  // Free the buffer and show result
  FreeMem(apiBuffer);
  ShowMessage(sMessage);
end;


"Carlos Azevedo" <carlos@sector.com.br> wrote:
>How to use the function Enumports to discover if the LPT1 port is install?