🚀 go-pugleaf

Wonder why you don't use IOTAMainMenuService.AddMenuItem just like 
GExperts, or CnWizards.

-- 
Lex Y. Li
http://lextm.blogspot.com

Code Beautifier Collection
http://code.google.com/p/lextudio

Linces wrote:
> How i create a Main Menu item in the Delphi IDE "Like GExperts do", i do 
> like code below, but dont work, plz look:

When reporting problem, it is best to provide more information about what 
isn't working.  For example, is there a menu item but it is disabled, do you 
get a crash, or do you get no menu item at all?  Have you set breakpoints in 
your code to see what is failing?  If so, where does it fail?

> type
>   TADPCHStickerWizard = class(TNotifierObject, IOTAWizard, IOTAMenuWizard)

IOTAMenuWizard is only meant to create a help menu item for your addin.  It 
isn't designed to add menu items anywhere in the main menu.

> procedure Register;

Set a breakpoint here, and be sure your addin is loading.

> procedure TADPCHStickerWizard.Execute;

This only runs when the user selects your help menu item, which probably 
isn't what you want.

> procedure InitWizard;

You probably don't want this to be an empty method.

If you have access to Delphi 7, look at the "D7IOTA.HLP" file for help on the 
OTA.  Also, see here for some examples:
http://www.gexperts.org/opentools/

Erik

Here's a snippet. Hack it a bit and you'll figure it out. This adds a menu 
item in the Tools menu. What you need to do is add this into a bpl project, 
add DesignIDE in the project uses clause, compile, install.



unit LibraryEditorExpert;

interface

uses ToolsAPI;

procedure Register;

implementation

uses
  SysUtils, Menus, LibraryEditorFormU;

type
  TUltraTurboDelphiLibraryEditorExpert = class(TInterfacedObject, 
IOTAWizard, IOTANotifier)
  private
    FLibraryEditorItem: TMenuItem;
    procedure AddMenuItems;
    procedure RemoveMenuItems;
  public
    constructor Create;
    destructor Destroy; override;
    function GetIDString: string;
    procedure Execute;
    function GetName: string;
    function GetState: TWizardState;
    procedure AfterSave;
    procedure BeforeSave;
    procedure Destroyed;
    procedure Modified;
    procedure LibraryEditorItemClick(Sender: TObject);
  end;

procedure Register;
begin
  RegisterPackageWizard(TUltraTurboDelphiLibraryEditorExpert.Create);
  TLibraryEditorForm.CreateLibraryEditorForm;
end;

{ TUltraTurboDelphiLibraryEditorExpert }

procedure TUltraTurboDelphiLibraryEditorExpert.AddMenuItems;
var
  MainMenu: TMainMenu;
  ToolsMenu: TMenuItem;
  i: Integer;
begin
  inherited;
  MainMenu := (BorlandIDEServices as INTAServices).MainMenu;

  // Use default position to start with.
  ToolsMenu := MainMenu.Items[8];

  // Find "Tools" menu in main menu bar.
  for I := 0 to MainMenu.Items.Count - 1 do
    if CompareText(MainMenu.Items[I].Name, 'ToolsMenu') = 0 then
    begin
      ToolsMenu := MainMenu.Items[I];
      Break;
    end;

  // Insert expert menu items.
  // References are kept so they can be freed when expert is removed.
  FLibraryEditorItem := Menus.NewItem('Ultra Turbo Delphi Library Editor', 
0, False, True,
    LibraryEditorItemClick, 0, 'UltraTurboDelphiLibraryEditorItem');
  ToolsMenu.InsertComponent(FLibraryEditorItem);
  ToolsMenu.Insert(0, FLibraryEditorItem);
end;

procedure TUltraTurboDelphiLibraryEditorExpert.AfterSave;
begin
  //
end;

procedure TUltraTurboDelphiLibraryEditorExpert.BeforeSave;
begin
  //
end;

constructor TUltraTurboDelphiLibraryEditorExpert.Create;
begin
  AddMenuItems;
end;

destructor TUltraTurboDelphiLibraryEditorExpert.Destroy;
begin
  RemoveMenuItems;
  inherited;
end;

procedure TUltraTurboDelphiLibraryEditorExpert.Destroyed;
begin
  TLibraryEditorForm.RemoveLibraryEditorForm;
end;

procedure TUltraTurboDelphiLibraryEditorExpert.Execute;
begin
  //
end;

function TUltraTurboDelphiLibraryEditorExpert.GetIDString: string;
begin
  Result := '{0EE9F5C4-4890-4600-BFFF-37C0A3633DFF}';
end;

function TUltraTurboDelphiLibraryEditorExpert.GetName: string;
begin
  Result := 'UltraTurboDelphi.UltraTurboDelphiLibraryEditor';
end;

function TUltraTurboDelphiLibraryEditorExpert.GetState: TWizardState;
begin
  Result := [wsEnabled];
end;

procedure TUltraTurboDelphiLibraryEditorExpert.Modified;
begin
  //
end;

procedure 
TUltraTurboDelphiLibraryEditorExpert.LibraryEditorItemClick(Sender: 
TObject);
begin
  TLibraryEditorForm.ShowLibraryEditorForm;
end;

procedure TUltraTurboDelphiLibraryEditorExpert.RemoveMenuItems;
begin
  FLibraryEditorItem.Free;
end;

initialization
finalization
  TLibraryEditorForm.RemoveLibraryEditorForm;

end.