🚀 go-pugleaf

"DelphiGuy" <luc.co@sympatico.ca> wrote in message
news:487402eb$2@newsgroups.borland.com...

> Hi everyone, my name is Luc and I'm currently looking for a way
> to get a specific information from this file:
>
> http://www.ecb.int/stats/eurofxref/eurofxref-daily.xml
>
> I need to get the currency and rate from this line:
> <Cube currency="USD" rate="1.5687" />

Since you are using MSXML directly, you can perform XPath queries via the
selectNodes() and selectSingleNode() methods instead of iterating the nodes
manually.  For example (untested):

    procedure TForm1.Button1Click(Sender: TObject);
    var
        i : Integer;
        Doc: IXMLDomDocument2;
        List : IXMLDomNodeList;
        Node: IXMLDomNode;
        Attrs: IXMLDOMNamedNodeMap;
    begin
        Memo1.Clear;

        Doc := CreateOleObject('Microsoft.XMLDOM') as IXMLDomDocument2;
        Doc.load('eurofxref-daily.xml');

        Doc.setProperty('SelectionLanguage', 'XPath');
        Doc.setProperty('SelectionNamespaces', 
'xmlns:gesmes=''http://www.gesmes.org/xml/2002-08-01'' 
xmlns:ecb=''http://www.ecb.int/vocabulary/2002-08-01/eurofxref''');

        // to retreive all currencies
        List := 
Doc.selectNodes('/gesmes:Envelope/ecb:Cube/ecb:Cube/ecb:Cube');
        for i := 0 to List.get_length-1 do
        begin
            Node := List.get_item(i);
            Attrs := Node.get_attributes;
            Memo1.Lines.Append(Format('Currency: %s, Rate: %s', 
[Attrs.getNamedItem('currency').get_text, 
Attrs.getNamedItem('rate').get_text]);
        end;

        // to retreive USD currency only
        Node := 
Doc.selectSingleNode('/gesmes:Envelope/ecb:Cube/ecb:Cube/ecb:Cube[@currency="USD"]');
        if Node <> nil then
            Memo1.Lines.Append('USD Currency is: ' + 
Node.get_attributes.getNamedItem('rate').get_text);
    end;

Refer to MSDN for more details:

    XPath Reference
    http://msdn.microsoft.com/en-us/library/ms256115.aspx


Gambit