🚀 go-pugleaf

Patricia Dilmore wrote:
> Maybe the problem lies with the report designer rather than the dmd.

Whenever you're using a DMD with groups, make sure that the report's 
autoSort property is false. Otherwise, you may very well get just one 
detail row per group.

As mentioned in the TFM, a rowset's canGetRow fires before the master-
detail link, so you can't rely on the masterRowset link to check the 
detail rows for that parent row. You must apply the constraint yourself:

** END HEADER -- do not remove this line
//
// Generated on 04/29/98
//
class claimprocsDataModule of DATAMODULE

   this.CLAIMS1 = new QUERY()
   this.CLAIMS1.parent = this
   with (this.CLAIMS1)
      left = 3
      top = 14
      sql = 'select * from "CLAIMS.dbf"'
      active = true
   endwith


   with (this.CLAIMS1.rowset)
      canGetRow = class::CLAIMS1_CANGETROW

   endwith

   this.PROCS1 = new QUERY()
   this.PROCS1.parent = this
   with (this.PROCS1)
      left = 11
      top = 14
      sql = 'select * from "PROCS.dbf"'
      active = true
   endwith


   with (this.PROCS1.rowset)

      filter = "TOS = 'X'"
      indexName = "CLAIMNO"
      masterRowset = parent.parent.claims1.rowset
      masterFields = "CLAIMNO"
   endwith



   this.rowset = this.claims1.rowset

   function claims1_canGetRow
      local lRet, procs
      try
        procs = this.parent.parent.procs1.rowset
        if procs.setRange( this.fields[ "CLAIMNO" ].value )
          lRet = not procs.endOfSet
        else
          lRet = false
        endif
      catch ( Exception e )
        lRet = true
      endtry
      return lRet

endclass


You need the TRY block because the canGetRow will fire when you first 
assign it, and at that point, there is no PROC rowset at that point. The 
CATCH should just return true to get that out of the way; otherwise, it 
will keep trying until it finds a row.

The test uses setRange(), which is the same mechanism that the 
masterRowset will use, so it's slightly redundant, but there's not much 
you can do about it (you might try coding a test to see if the parent row 
has changed key values, but it may not be worth the trouble). It checks 
if there are any matches for the index, and if there are, whether there 
are any matches for the filter you have.

-- 
//Ken@Inprise
<Please follow-up to newsgroup; do not reply to email>