🚀 go-pugleaf

Reid Roman wrote:
> 
> Eric wrote:
> >
> > Hello,
> >
> > Would you please to give me a simple example to implement MouseEnter and
> > MouseExit on SpeedButton ????
> 
> Use the onmousemove event for the form, this gives you the x and y
> co-ordinates of the mouse pointer, something like:

This technique might not give you all the right results. For instance,
what if, on form creation, the cursor is inside the button? The event
doesn't get triggered immediately. If it's not too much of a pain (i.e.
you've already got a zillion TSpeedButtons created), you might consider
writing your own TSpeedButton descendent that traps the MOUSEENTER and
MOUSELEAVE message. Here's an example:


unit PsSpeedButton;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms,
  Dialogs, Buttons;

type
  TPsSpeedButton = class(TSpeedButton)
  private
  protected
    FOnMouseEnter: TNotifyEvent;
    FOnMouseLeave: TNotifyEvent;
    procedure DoMouseEnter; virtual;
    procedure DoMouseLeave; virtual;
    procedure CMMouseEnter(var Msg: TMessage); message CM_MOUSEENTER;
    procedure CMMouseLeave(var Msg: TMessage); message CM_MOUSELEAVE;
  public
  published
    property OnMouseEnter: TNotifyEvent read FOnMouseEnter
                                        write FOnMouseEnter;
    property OnMouseLeave: TNotifyEvent read FOnMouseLeave
                                        write FOnMouseLeave;
  end;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('Professional Software', [TPsSpeedButton]);
end;

procedure TPsSpeedButton.DoMouseEnter;
begin
  if Assigned(OnMouseEnter) then OnMouseEnter(Self);
end;

procedure TPsSpeedButton.DoMouseLeave;
begin
  if Assigned(OnMouseLeave) then OnMouseLeave(Self);
end;

procedure TPsSpeedButton.CMMouseEnter(var Msg: TMessage);
begin
  DoMouseEnter;
end;

procedure TPsSpeedButton.CMMouseLeave(var Msg: TMessage); 
begin
  DoMouseLeave;
end;

end.


Dave
-- 
http://www.csd.net/~daves