🚀 go-pugleaf

I simulated a 7 inverter CMOS ring oscillator on spice 2 and spice 3
on several machines running unix BSD4.2 (or derivatives) to compare
results. I got some rather interesting statistics, which, I thought
might interest other users. I am posting the statistics as well as the
spice deck that I ran. No conclusions drawn; I tried as far as
possible to run the jobs on lightly loaded machines.
All times are from /bin/time.

Badri Lokanathan
--
spice deck cring.in run on spice 3a7: 
MACHINE        HARDWARE SPECS.          REAL        USER        SYS
-------        ---------------          ----        ----        ---
Pyramid 90x    8M core, no f.p.a.      273.3       244.1        3.6
Sun 3/280      8M core, 68881 acc.     258.1       252.9        2.3
VAX 11/750     4M core, f.p.a.         527.5       158.5        7.7
VAX 11/750     2M core, f.p.a.         451.0       414.7        8.3
VAX 11/750     2M core, no f.p.a.      494.8       432.0       11.8
-------------------------------------------------------------------
spice deck cring.in run on spice 2g6: 
MACHINE        HARDWARE SPECS.          REAL        USER        SYS
-------        ---------------          ----        ----        ---
Pyramid 90x    8M core, no f.p.a.      374.7       326.7        7.2
Sun 3/280      8M core, 68881 acc.     304.2       294.9        1.7
VAX 11/750     4M core, f.p.a.         732.5       241.6       15.4
VAX 11/750     2M core, f.p.a.         662.0       560.1       17.2
VAX 11/750     2M core, no f.p.a.      722.6       592.7       24.0
-------------------------------------------------------------------
spice deck cring.in: 
*  CMOS Ring oscillator (7 inverters)
*
*  Transistors :
mq1n   2     1     0     0     CMOSN l=3u w=4.5u
mq1p   2     1   100   100     CMOSP l=3u w=4.5u
mq2n   3     2     0     0     CMOSN l=3u w=4.5u
mq2p   3     2   100   100     CMOSP l=3u w=4.5u
mq3n   4     3     0     0     CMOSN l=3u w=4.5u
mq3p   4     3   100   100     CMOSP l=3u w=4.5u
mq4n   5     4     0     0     CMOSN l=3u w=4.5u
mq4p   5     4   100   100     CMOSP l=3u w=4.5u
mq5n   6     5     0     0     CMOSN l=3u w=4.5u
mq5p   6     5   100   100     CMOSP l=3u w=4.5u
mq6n   7     6     0     0     CMOSN l=3u w=4.5u
mq6p   7     6   100   100     CMOSP l=3u w=4.5u
mq7n   1     7     0     0     CMOSN l=3u w=4.5u
mq7p   1     7   100   100     CMOSP l=3u w=4.5u
*
*  Voltage cards :
vdd 100     0     dc     5V
*
*  Analysis cards :
.tran 100ps 20ns
.plot tran v(1) v(7)
.ic v(1)=0 v(3)=0 v(5)=0 v(7)=0
*
*  Model cards :
.MODEL CMOSN NMOS (VTO=0.83 KP=33U GAMMA=1.36 PHI=0.6
+ LAMBDA=0.016 PB=0.8 JS=10N LD=0.28U TOX=50N NSUB=1E16
+ UO=200 UEXP=0.1 UCRIT=4E4 VMAX=100K XJ=0.4U
+ DELTA=1.24 NFS=0 NEFF=2 NSS=0 TPG=1.0 RSH=25
+ CGSO=0.5N CGDO=0.5N CJ=0.32M MJ=0.5 CJSW=0.9N MJSW=0.33
+ CGBO=0 FC=0.5 LEVEL=2)
.MODEL CMOSP PMOS (VTO=-0.89 KP=15U GAMMA=0.88 PHI=0.6
+ LAMBDA=0.047 PB=0.8 JS=10N LD=0.28U TOX=50N NSUB=1.12E14
+ UO=100 UEXP=0.1 UCRIT=20E4 VMAX=100K XJ=0.4U
+ DELTA=1.94 NFS=0 NEFF=2 NSS=0 TPG=-1.0 RSH=95
+ CGSO=0.4N CGDO=0.4N CJ=0.2M MJ=0.5 CJSW=0.45N MJSW=0.33
+ CGBO=0 FC=0.5 LEVEL=2)
.end