🚀 go-pugleaf

Checksum: 2881625009 (verify with brik -cv)
Submitted-by: Kati Sinenmaa <sinenmaa@cc.helsinki.fi>
Posting-number: Volume 6, Issue 18
Archive-name: tyko_ks/part02

BEGIN_RPL tyko.rpl
%%HP: T(3)A(D)F(.);
DIR
  START.
\<< NOVA { { "SETUP"
  \<< CLEAR SETUP
  \>> } { "JULIA"
  \<< CLEAR 'DN'
PURGE
"Julian Day.fraction"
":JDAY:" INPUT OBJ\->
DUP DUP 'JD' STO FP
24 * 12 + TZ + DL +
F24 'LT' STO LT TZ
- DL - 24 / - 'JD0'
STO CHUT JD0 CADA
'DT' STO NOVA
  \>> } { "LT.ST"
  \<< CLEAR JD0 GWUT
LT TZ - DL -
1.00273790935 * +
F24 DUP \->HMS "GMST"
\->TAG SWAP \GlM 15 / +
F24 DUP \GD\165 \Ge COS *
15 / + \->HMS "AST"
\->TAG SWAP \->HMS
"MST" \->TAG
  \>> } { "ST.LT"
  \<< CLEAR JD0 GWUT
LT \GlM 15 / - F24
DUP \->HMS "GMST"
\->TAG SWAP ROT - F24
.99726956633 * \->HMS
TZ + DL + F24 "LT"
\->TAG
  \>> } { "SPACE"
  \<< CLEAR SUDEP
  \>> } { "END"
  \<< WIPE PURGE 2
MENU
  \>> } } TMENU
\>>
ASCAL
\<< -16 CF -19 SF
" Type MONTH and YEAR"
":MM YYYY:" INPUT
OBJ\-> \-> m y
  \<<
    IF m 0 == m 13
\>= OR
    THEN
"Are you an Alien ?"
DOERR
    END m 1 y JDAY
OVER 3 + 7 / FP 7 *
0 RND 1 + + 7 / 0
RND ERASE -1 39
XRNG 0 24 YRNG
CLLCD
"A calendar v1.0 by KS"
1 DISP (0,0) (0,21)
(3,0) (3,21) (8,0)
(8,3) (0,0) (13,0)
(8,0) (8,3) (13,0)
(13,3) 1 6
    FOR j LINE
    NEXT 1 7
    FOR j 38 j 3 *
\->V2 0 j 3 * \->V2
LINE 43 j 5 * - 3
\->V2 43 j 5 * - 21
\->V2 LINE
    NEXT PICT RCL 1
7
    FOR j -1.1 j 5
* + 20.3 \->V2 DAMO j
1 + GET 1 \->GROB GOR
    NEXT SWAP DUP
    IF 0 ==
    THEN 52
    ELSE DUP
    END 1 \->GROB ROT
(.5,17) ROT GOR
(7,23.5) JG DAMO m
8 + GET y \->STR + +
1 \->GROB GOR SWAP 1
+ DUP DUP DUP DUP 6
ROLL 0 4
    FOR j .5 14 j 3
* - \->V2 ROT j + 1
\->GROB GOR
    NEXT -42 CF
SWAP DUP 1 + 7 / FP
7 * 0 RND 'c' STO 1
'w' STO 1 m + 1 y
JDAY DROP SWAP -
    IF y 1991 \<= y
2099 \>= OR
    THEN 1 SWAP
"Alarm detect disabled"
1 DISP
    ELSE DUP y
1000000 / DUP .01 +
m + SWAP ROT 100 /
+ m + 23.5959 2
\->LIST FINDALARM
SWAP FINDALARM -
DUP
      IF 0 ==
      THEN DROP
SWAP (19,2) "No"
      ELSE ROT
(19,2) ROT ABS \->STR
      END
" alarms" + 1
\->GROB GOR 1 ROT
    END
    FOR j
      IF c 0 \=/ c 7
\=/ AND
      THEN c 5 *
1.3 - 20 w 3 * -
\->V2 j 1 \->GROB GOR c
1 + 'c' STO
      ELSE 33.7 20
w 3 * - \->V2 j 1
\->GROB GOR 1 'c' STO
w 1 + 'w' STO
      END
    NEXT PICT STO {
} PVIEW { w c PPAR
} PURGE
  \>>
\>>
GSTR
\<< STD \-> y
  \<< y 19 MOD y 100
MOD y 100 / IP DUP
DUP 4 MOD 2 * SWAP
4 / IP ROT DUP DUP
8 + 25 / IP - 1 + 3
/ IP SWAP ROT -
SWAP - 4 PICK 19 *
+ 15 + 30 MOD ROT
DUP 4 / IP 2 * SWAP
4 MOD SWAP 3 PICK -
SWAP - ROT + 32 + 7
MOD DUP 22 * 3 PICK
11 * + 4 ROLL + 451
/ IP 7 * ROT ROT +
SWAP - 114 + DUP 31
/ IP SWAP 31 MOD 1
+ \-> M D
    \<< { "March "
"April " } M 2 -
GET D y ABS 10 y
ABS \->STR SIZE DUP
FIX ^ / + y SIGN *
\->STR + STD M
      IF 4 <
      THEN D 22 -
DUP
        IF 0 ==
        THEN DROP
"April " 30
        ELSE "May "
SWAP
        END
      ELSE D 9 +
DUP
        IF 31 >
        THEN
"June " SWAP 31 -
        ELSE "May "
SWAP
        END
      END \->STR +
"Ascension Day"
\->TAG
    \>>
  \>>
\>>
JSTR
\<< STD \-> y
  \<< y 4 MOD 2 * y 7
MOD 4 * + y 19 MOD
19 * 15 + 30 MOD
SWAP OVER - 34 + 7
MOD 114 + + DUP 31
/ IP { "March "
"April " } SWAP 2 -
GET SWAP 31 MOD 1 +
y ABS 10 y ABS \->STR
SIZE DUP FIX ^ / +
y SIGN * \->STR + STD
"Julian Easter"
\->TAG
  \>>
\>>
JDAY
\<< STD \-> m D V
  \<< D m
    IF 3 \>=
    THEN m 3 - V
    ELSE m 9 + V 1
-
    END DUP 4712 +
365.25 * IP SWAP
100 / 49 + IP .75 *
IP 38 - V \-> D m y g
W
    \<< y m 30.6 * .5
+ IP 59 D + + + DUP
g - "GreCal" \->TAG
SWAP "JulCal" \->TAG
      IF JG SIZE 10
<
      THEN SWAP
DROP DUP 0
      ELSE DROP DUP
W 1 - 100 / 49 + IP
.75 * IP 38 -
      END W 1 -
4712 + 365.25 * IP
365 + SWAP - -
"DayNum" \->TAG
    \>>
  \>>
\>>
CADA
\<< STD 0 RND \-> J
  \<< J 1 + 7 / FP 7
* 0 RND 1 + DAMO
SWAP GET
    IF JG SIZE 10
==
    THEN J 4479.5 -
36524.25 / IP .75 *
.5 + IP 37 - J +
    ELSE J
    END DUP 59.25 -
365.25 MOD IP DUP
.5 + 30.6 / IP 2 +
12 MOD 9 + DAMO
SWAP GET SWAP .5 +
30.6 MOD IP 1 + ROT
365.25 / IP 4712 -
DUP ABS DUP 10 SWAP
\->STR SIZE DUP FIX ^
/ ROT + SWAP SIGN *
\->STR + + STD
  \>>
\>>
EOFT
\<< 2451545 -
.00273790931 *
.779072 + FP 360 *
F36 \-> L
  \<< '-106.2*SIN(L)+
596.2*SIN(2*L)+4.4*
SIN(3*L)-12.7*SIN(4
*L)-428.9*COS(L)-
2.1*COS(2*L)+19.3*
COS(3*L)' EVAL 3600
/ 12 SWAP - TZ \GlM
15 / - + DL +
  \>>
\>>
GWUT
\<< 2451545 - 36525 /
DUP DUP 3 ^
-.0000062 * .093104
ROT 2 ^ * +
8640184.81287 ROT *
+ 24110.54841 +
3600 / F24 DUP \->HMS
"GMST0" \->TAG SWAP
\>>
EQSO
\<<
"Equinox and Solstice"
":MM YYYY:" INPUT
OBJ\-> \-> M Y
  \<< M 3 / FP
    IF 0 ==
    THEN Y 2000 -
1000 / 'P' STO DAES
M 3 / GET EVAL 'P'
PURGE DUP FP 24 *
12 + TZ + DL + F24
DUO \->HMS "LT" \->TAG
ROT ROT TZ - DL -
24 / - CADA
    END
  \>>
\>>
CONV
\<< -16 CF \-> l b
  \<< l COS l SIN \Ge
COS * b TAN \Ge SIN *
- \->V2 -16 SF V\-> F36
SWAP DROP "RA" \->TAG
b SIN \Ge COS * b COS
\Ge SIN l SIN * * +
ASIN "DECL" \->TAG
-16 CF
  \>>
\>>
EQEC
\<< { { "MEAN"
  \<< \Ge \GD\Ge - 'E' STO
CONT
  \>> } { "APPAR"
  \<< \Ge 'E' STO CONT
  \>> } } TMENU
"Select conversion"
PROMPT -16 CF STD
HMS\-> '\Gd' STO HMS\->
15 * '\Ga' STO \Gd SIN
E COS * \Gd COS E SIN
\Ga SIN * * - ASIN
"\Gb" \->TAG \Gd COS \Ga
COS * \Gd SIN E SIN *
\Gd COS E COS \Ga SIN *
* + \->V2 -16 SF V\->
SWAP DROP DUP
  IF 0 <
  THEN 360 +
  END "\Gl" \->TAG { \Ga
\Gd E } PURGE -16 CF
SWAP 0 MENU
\>>
SETUP
\<< { { "DATE"
  \<<
"DATE-form MM DD YYYY"
":DATE:" INPUT OBJ\->
JDAY 'DN' STO .5 -
'JD0' STO JD0 LT TZ
- DL - 24 / + 'JD'
STO JD0 CADA 'DT'
STO NOVA
  \>> } { "TIME"
  \<<
"TIME-format HH.MMSS"
":L/ST:" INPUT OBJ\->
HMS\-> DUP TZ - DL -
24 / JD0 + 'JD' STO
'LT' STO CHUT NOVA
  \>> } { "LONG"
  \<<
"Longitude in decimals"
"
West negative
" +
":\Gl:" INPUT OBJ\->
'\GlM' STO NOVA
  \>> } { "LATIT"
  \<<
"Latitude in decimals"
"
-90 < \O/ < 90
" +
":\O/:" INPUT OBJ\->
'\O/' STO NOVA
  \>> } { "ZONE"
  \<<
"Integer  -12  to  12"
"
West=neg
" +
":Time Zone:" INPUT
OBJ\-> 'TZ' STO JD0
LT TZ - DL - 24 / +
'JD' STO CHUT NOVA
  \>> } { "BACK"
  \<< 0 MENU NOVA
  \>> } { "DST"
  \<< 1 DL 1 * - 'DL'
STO CHUT NOVA
  \>> } { "CALE"
  \<< { "Gregorian "
"  Julian " } JG
SIZE 8 - GET 'JG'
STO JD0 CADA 'DT'
STO NOVA
  \>> } } TMENU NOVA
\>>
SOLAR
\<< 1400 .12 BEEP
1000 .2 BEEP { {
"Merc"
  \<< CAL1 OBJ\-> DROP
EVAL 'R' STO EVAL
'\Gb' STO EVAL 3600 /
L1 + '\Gl' STO 6.72 .5
87 G1 1 CONT
  \>> } { "Venu"
  \<< CAL2 OBJ\-> DROP
EVAL 'R' STO EVAL
'\Gb' STO EVAL 3600 /
L2 + '\Gl' STO 16.68
-4. 224 G2 2 CONT
  \>> } { "Mars"
  \<< CAL4 OBJ\-> DROP
EVAL 'R' STO EVAL
'\Gb' STO EVAL 3600 /
L3 + '\Gl' STO 9.36
-1.12 686 G3 3 CONT
  \>> } { "Jupit"
  \<< CAL5 OBJ\-> DROP
EVAL 'R' STO EVAL
'\Gb' STO EVAL 3600 /
L4 + '\Gl' STO 196.88
-9.33 4360 G4 4
CONT
  \>> } { "Satur"
  \<< CAL6 OBJ\-> DROP
EVAL 'R' STO EVAL
'\Gb' STO EVAL 3600 /
L5 + '\Gl' STO 165.46
-8.5 10740 G5 5
CONT
  \>> } { "Uran"
  \<< CAL7 OBJ\-> DROP
EVAL 'R' STO EVAL
'\Gb' STO EVAL 3600 /
L6 + '\Gl' STO 70.04
-7.2 30690 G6 6
CONT
  \>> } { "Neptu"
  \<< CAL8 OBJ\-> DROP
EVAL 'R' STO EVAL
'\Gb' STO EVAL 3600 /
L7 + '\Gl' STO 67
-6.86 60181 G7 7
CONT
  \>> } { "Pluto"
  \<< CAL9 OBJ\-> DROP
EVAL 'R' STO EVAL
'\Gb' STO EVAL 3600 /
L8 + '\Gl' STO 4.14
-1 90000 G8 8 CONT
  \>> } { "Moon"
  \<< CALM OBJ\-> DROP
EVAL '\GD' STO r
23454.78 * 'R' STO
EVAL 3600 / DUP '\Gb'
STO 'b' STO EVAL
3600 / L9 \GD\165 + +
F36 DUP '\Gl' STO 'l'
STO \Gb COS \Gl \GlS -
COS * ACOS '\165' STO
\GD R \165 COS * - R \165
SIN * -16 CF \->V2
-16 SF V\-> F36 '\Gm'
STO DROP 936.75 \GD /
\->HMS 29 G9 9 CONT
  \>> } { "CALE"
  \<< { "Gregorian "
"  Julian " } JG
SIZE 8 - GET 'JG'
STO JD0 CADA 'DT'
STO NOVA
  \>> } } TMENU
"   Select  Object"
PROMPT 'n' STO *
360 / NEG JD + CADA
'\Gt' STO
  IF n 9 <
  THEN \Gl F36 '\Gl'
STO \Gb 3600 / '\Gb'
STO GEOC 5 R \GD * 1
l \Gl - COS + .5 * \v/
/ LOG * + 'V' STO r
r * \GD \GD * + R R * -
2 r \GD * * / ACOS
'\165' STO R R * \GD \GD *
+ r r * - 2 R \GD * *
/ ACOS '\Gm' STO \GD /
  END 'SD' STO l b
CONV '\Gd' STO '\Ga'
STO AARS 400 .2
BEEP 800 .2 BEEP
1600 .2 BEEP { {
"PICT"
  \<< DRAV
  \>> } { "FILE"
  \<< CROB
  \>> } { "DATA"
  \<< PDRV
  \>> } { "NEW"
  \<< SOLAR
  \>> } { "END"
  \<< { D L1 G1 F1 L2
G2 F2 L3 F3 L4 F4
L5 G5 F5 L6 G6 F6
L7 G7 F7 L8 G8 F8
G9 F9 \Gt l b \165 \Gm \GD }
PURGE WIPE PURGE 2
MENU
  \>> } } TMENU
\>>
SUDEP
\<< DEG MISC 900 .13
BEEP 500 .2 BEEP {
{ "SUN"
  \<< 10 'n' STO r
'R' STO 15.99 R /
\->HMS 'SD' STO .62
'BV' STO -26.78 'V'
STO JD0 .5 + EOFT
'ET' STO \GlS '\Gl' STO
\Gl \GbS '\Gb' STO \Gb CONV
'\Gd' STO '\Ga' STO
AARS SDRV
  \>> } { "SOLAR"
  \<<
[ .374897 .259091 .827362 .700695 .485541 .566441 .505498 .292498 .987353
.849694
.089608 .814794 .133295 .882987 .821218 .870169 .400589 .664614 .846912
.725368
.480856 .663854 .04102 .357355 ]
[ .03629164709 .0367481952 .03386319198 .011367714 .01136759566 .01136762384
.00445046867 .00445040017 .00145575328 .00145569465 .00023080893
.00023080893
.00009294371 .00009294371 .00009294371 .00003269438 .00003269438
.00003265562
.00001672092 .00001672092 .00001663715 .00001115482 .00001104864
.00001104864 ]
C * + OBJ\-> DROP {
F8 G8 L8 F7 G7 L7
F6 G6 L6 F5 G5 L5
F4 L4 F3 L3 F2 L2
F1 G1 L1 D F9 G9 }
\-> i
    \<< 1 24
      FOR j FP 360
* i j GET STO
      NEXT
    \>> SOLAR
  \>> } { "STARS"
  \<< DEEP
  \>> } { "CALE"
  \<< { "Gregorian "
"  Julian " } JG
SIZE 8 - GET 'JG'
STO JD0 CADA 'DT'
STO NOVA
  \>> } { "BACK"
  \<< START.
  \>> } { "END"
  \<< WIPE PURGE 2
MENU
  \>> } } TMENU
\>>
MISC
\<< STD CLLCD
"Wait ..." 1 DISP
JD0 GWUT LT TZ - DL
- 1.00273790935 * +
\GlM 15 / + F24 'ST'
STO HMS\-> 'GST' STO
JD 2451545 - DUP
'C' STO 36525 / 't'
STO t 1 + 'T' STO
.606434
.03660110129 C * +
.779072
.00273790931 C * +
.993126 .0027377785
C * + .140023
.00445036173 C * +
.053856
.00145561327 C * +
.056531
.00023080893 C * +
{ G4 G3 G2 GS LS L9
} DEG \-> i
  \<< 1 6
    FOR j FP 360 *
i j GET STO
    NEXT 125.044555
1934.1361849 t * -
.0020762 t 2 ^ * +
t 3 ^ 467410 / + t
4 ^ 60616000 / +
'\GW' STO -.00172 \GW
SIN * .000132 2 LS
* SIN * - .000023 2
L9 * SIN * -
.000021 2 \GW * SIN *
+ HMS\-> '\GD\165' STO
23.2621448 .0046815
t * - .000000059 t
2 ^ * - .0000001813
t 3 ^ * + HMS\->
.00092 \GW COS *
.000057 2 LS * COS
* + .00001 2 L9 *
COS * + .000009 2 \GW
* COS * - HMS\-> DUP
'\GD\Ge' STO + '\Ge' STO
t 10 / 'p' STO CALS
OBJ\-> DROP EVAL 'r'
STO EVAL 3600 / LS
+ F36 \GD\165 .0052 r /
- + '\GlS' STO EVAL
SWAP EVAL p * +
100000000 / R\->D NEG
'\GbS' STO
  \>>
\>>
CROB
\<< ERASE NM n GET 2
\->GROB PICT STO PICT
RCL { # 0d # 15d }
DT 1 \->GROB GOR 6
FIX { # 60d # 7d }
"GMST0= " GST \->HMS
ZZ { # 71d # 14d }
"LST= " ST \->HMS ZZ
{ # 0d # 23d }
"\Gl= " \Gl \->HMS ZZ {
# 0d # 29d } "\Gb= "
\Gb \->HMS ZZ { # 0d
# 50d } "r= " R ZZ
{ # 0d # 57d }
"\GD= " \GD ZZ { # 0d
# 37d } "\Ga= " \Ga 15
/ \->HMS ZZ { # 0d
# 43d } "\Gd= " \Gd
\->HMS ZZ { # 60d
# 21d } "AZ= " A
\->HMS ZZ { # 60d
# 27d } "a = " a
\->HMS ZZ { # 53d
# 58d } "\Gt= " \Gt + 1
\->GROB GOR 3 FIX {
# 66d # 40d }
"RISE = " RI ZZ {
# 65d # 46d }
"  ET = " ET \->HMS ZZ
{ # 65d # 52d }
" SET = " SE ZZ {
# 57d # 33d } "D= "
SD ZZ { # 94d # 33d
} "M= " V ZZ {
# 60d # 1d }
"JDAY= " JD ZZ {
# 0d # 9d } "CAL="
JG + 1 \->GROB GOR
STD PICT STO PICT
RCL \->LCD { } PVIEW
\>>
DRAV
\<< -16 CF -19 SF
ERASE -35 35 XRNG
-15 15 YRNG CLLCD
"Drawing system ..."
1 DISP DEG
  IF 'IMAG' VTYPE 0
<
  THEN 3 FIX (0,0)
1.5 0 360 ARC
(-35,0) (0,0) LINE
1 RES CONIC 'X'
INDEP 'Y' DEPND 'X^
2/196+Y^2/16=1'
STEQ DRAW 'X^2/625+
Y^2/81=1' STEQ DRAW
PICT RCL { # 0d
# 8d } "Earth" 1
\->GROB GOR 'IMAG'
STO
  END IMAG { # 0d
# 0d } \GlS 0 CONV ST
15 * ROT - \-> d h
  \<< \GlS 180 + h COS
d COS \O/ SIN * * d
SIN \O/ COS * - h SIN
d COS * \->V2 -16 SF
V\-> SWAP DROP 180 -
+ F36 \-> x
    \<<
      IF n 2 \<=
      THEN \Gl COS 14
* \Gl SIN 4 * R\->C 1.2
0 360 ARC \GlS 180 -
DUP COS 25 * SWAP
SIN 9 * R\->C DUP 1.8
0 360 ARC x COS 2.3
* x SIN 2.3 * R\->C +
.6 0 360 ARC
      ELSE
        IF n 9 ==
        THEN \GlS 180
- DUP COS 25 * SWAP
SIN 9 * R\->C DUP 1.5
0 360 ARC x COS 2.3
* x SIN 2.3 * R\->C +
.6 0 360 ARC PICT
RCL GOR \GlS COS 25 *
\GlS SIN 9 * R\->C
CENTR { # 0d # 0d }
'X' INDEP 'Y' DEPND
CONIC 'X^2/81+Y^2/9
=1' STEQ DRAW \Gl COS
9 * \Gl SIN 3 * R\->C
1.1 0 360 ARC
        ELSE \GlS 180
- DUP COS 14 * SWAP
SIN 4 * R\->C DUP 1.5
0 360 ARC x COS 2.3
* x SIN 2.3 * R\->C +
.6 0 360 ARC \Gl COS
25 * \Gl SIN 9 * R\->C
1.5 0 360 ARC
        END
      END 'EQ'
PURGE PICT RCL GOR
{ # 0d # 0d } NM n
GET 2 \->GROB GOR {
# 70d # 0d } DT 1
\->GROB GOR { # 1d
# 58d } "\Gb= "
      IF n 9 ==
      THEN \GD 6378 '
1_km' * *
      ELSE R '1_AU'
*
      END \Gb SIN * 5
FIX ZZ { # 88d
# 58d } "LT= " LT
\->HMS ZZ STD -16 CF
PICT STO PICT RCL
\->LCD { } PVIEW
    \>>
  \>>
\>>
PDRV
\<< STD -19 SF "G" n
+ STR\-> F36 "L" n +
STR\-> F36 "F" n +
STR\-> F36 \-> M L F
  \<< 6 FIX "L = " L
\->HMS + "  M = " M
\->HMS + + "\pi = " L M
- F36 \->HMS +
"  \GW = " L F - F36
\->HMS + + "T = " t +
"  \Ge = " \Ge \->HMS + +
"\GD\165 = " \GD\165 \->HMS
10000 * + "  \GD\Ge = "
\GD\Ge \->HMS 10000 * + +
"l = " l \->HMS +
"  b = " b \->HMS + +
"\165 = " \165 \->HMS +
"  \GDt = " \GD 8.31675
* \->HMS + + "i = " \Gm
\->HMS + "  k = " 1 \Gm
COS + 2 / + + STD
-6.7 6.5 XRNG 0 8.2
YRNG DT " " LT + +
  \>> 2 \->GROB PICT
STO PICT RCL 1 7
  FOR j -6.5 j \->V2
ROT 1 \->GROB GOR
  NEXT PICT STO { }
PVIEW
\>>
SDRV
\<< -16 CF -19 SF 6
FIX "          " DT
+ "R= " R + " UT= "
UT + + "\Gl = " \Gl
\->HMS + "  \Gb = " \Gb
\->HMS + + "\Ga =  " \Ga
15 / \->HMS +
"  \Gd = " \Gd \->HMS + +
"AZI = " A +
"  ALT = " a + + 3
FIX "RISE " RI +
" SET " SE + +
" ET= " ET \->HMS + +
"V= " V + " B-V= "
BV + + " SD= " SD +
+ "\GD\165 " \GD\165 \->HMS
10000 * + " \GD\Ge " \GD\Ge
\->HMS 10000 * + +
STD " \Ge " \Ge \->HMS +
+ ERASE -6.7 6.5
XRNG .3 8.3 YRNG
STD NM n GET 2
\->GROB PICT STO PICT
RCL 1 8
  FOR j -6.5 j \->V2
ROT 1 \->GROB GOR
  NEXT PICT STO { }
PVIEW
\>>
CHUT
\<< LT TZ - DL - \-> U
  \<< U F24 \->HMS
    IF U 0 < U 24 \>=
OR
    THEN {
" yesterday" ""
" tomorrow" } U
SIGN 2 + GET
    ELSE " today"
    END + 'UT' STO
  \>>
\>>
DEEP
\<< 'SD' PURGE
  IF 'SDAT' VTYPE 0
<
  THEN
"Star data not exist"
DOERR
  ELSE 1 'n' STO {
{ "PICK"
    \<< NEWS
    \>> } { "CONT"
    \<< 1.396971 t *
.0003086 t t * * +
.013056 t *
.0000092 t t * * -
5.12362 .241614 t *
.0001122 t t * * +
+ SDAT n GET OBJ\->
DROP 'V' STO 'BV'
STO "_pc " + 'R'
STO \-> a b c A B
      \<< B A c + SIN
b * + '\Gb' STO A a B
TAN A c + COS b * *
- + '\Gl' STO n 10 +
'n' STO \Gl \Gb CONV
'\Gd' STO '\Ga' STO
AARS SDRV
      \>>
    \>> } { "BACK"
    \<< 0 MENU
    \>> } { "END"
    \<< WIPE PURGE 2
MENU
    \>> } } TMENU
  END
\>>
AARS
\<< -16 CF ST 15 * \Ga
- \-> h
  \<< h COS \Gd COS \O/
SIN * * \Gd SIN \O/ COS
* - h SIN \Gd COS *
\->V2 -16 SF V\-> F36
\->HMS 'A' STO DROP h
COS \Gd COS \O/ COS * *
\O/ SIN \Gd SIN * +
ASIN \->HMS 'a' STO
    CASE n 10 ==
      THEN -.8333
      END n 9 ==
      THEN \GD INV
ASIN .7275 * .5667
-
      END n 9 \=/ n
10 \=/ AND
      THEN -.5667
      END
    END
    IF n 10 \=/
    THEN \Ga 15 / GST
- TZ \GlM 15 / - + DL
+ F24 'ET' STO
    END SIN \Gd COS \O/
COS * / \Gd TAN \O/ TAN
* - DUP -16 CF
    IF ABS 1 >
    THEN DROP
      IF a 0 >
      THEN "Above"
      ELSE "Below"
      END "Horizon"
    ELSE ACOS 15 /
ET OVER - F24 \->HMS
SWAP ET + F24 \->HMS
    END 'SE' STO
'RI' STO
  \>>
\>>
DAES
\<< { '2451623.80984+
365242.37404*P+
.05169*P^2-.00411*P
^3-.00057*P^4' '
2451716.56767+
365241.62603*P+
.00325*P^2+.00888*P
^3-.0003*P^4' '
2451810.21715+
365242.01767*P-
.11575*P^2+.00337*P
^3+.00078*P^4' '
2451900.05952+
365242.74049*P-
.06223*P^2-.00823*P
^3+.00032*P^4' }
\>>
GEOC
\<< -16 CF R \Gb SIN *
R 2 ^ r 2 ^ + DUP 2
R r \GlS \Gl - 180 +
COS * * * SWAP OVER
- \v/ '\GD' STO \Gb COS *
- \v/ / ASIN 'b' STO
\Gb COS \Gl COS R * * r
\GlS COS * + R \Gb COS
\Gl SIN * * r \GlS SIN
* + \->V2 -16 SF V\->
F36 'l' STO DROP
\>>
CALM
\<< { '22640*SIN(G9)-
4586*SIN(G9-2*D)+
2370*SIN(2*D)+769*
SIN(2*G9)-668*SIN(
GS)-412*SIN(2*F9)-
212*SIN(2*G9-2*D)-
206*SIN(G9-2*D+GS)+
192*SIN(G9+2*D)+165
*SIN(2*D-GS)+148*
SIN(G9-GS)-125*SIN(
D)-110*SIN(G9+GS)-
55*SIN(2*F9-2*D)-45
*SIN(G9+2*F9)+40*
SIN(G9-2*F9)-38*SIN
(G9-4*D)+36*SIN(3*
G9)-31*SIN(2*G9-4*D
)+28*SIN(G9-2*D-GS)
-24*SIN(2*D+GS)+19*
SIN(G9-D)+18*SIN(D+
GS)+15*SIN(G9+2*D-
GS)+14*SIN(2*G9+2*D
)+14*SIN(4*D)-13*
SIN(3*G9-2*D)-11*
SIN(G9+16*LS-18*L2)
+10*SIN(2*G9-GS)+9*
SIN(G9-2*F9-2*D)+9*
COS(G9+16*LS-18*L2)
-9*SIN(2*G9-2*D+GS)
-8*SIN(G9+D)+8*SIN(
2*D-2*GS)-8*SIN(2*
G9+GS)-7*SIN(2*GS)-
7*SIN(G9-2*D+2*GS)+
7*SIN(\GW)-6*SIN(G9-2
*F9+2*D)-6*SIN(2*F9
+2*D)-4*SIN(G9-4*D+
GS)+4*T*COS(G9+16*
LS-18*L2)-4*SIN(2*
G9+2*F9)+4*T*SIN(G9
+16*LS-18*L2)+3*SIN
(G9-3*D)-3*SIN(G9+2
*D+GS)-3*SIN(2*G9-4
*D+GS)+3*SIN(G9-2*
GS)+3*SIN(G9-2*D-2*
GS)-2*SIN(2*G9-2*D-
GS)-2*SIN(2*F9-2*D+
GS)+2*SIN(G9+4*D)+2
*SIN(4*G9)+2*SIN(4*
D-GS)+2*SIN(2*G9-D)
' '18461*SIN(F9)+
1010*SIN(G9+F9)+
1000*SIN(G9-F9)-624
*SIN(F9-2*D)-199*
SIN(G9-F9-2*D)-167*
SIN(G9+F9-2*D)+117*
SIN(F9+2*D)+62*SIN(
2*G9+F9)+33*SIN(G9-
F9+2*D)+32*SIN(2*G9
-F9)-30*SIN(F9-2*D+
GS)-16*SIN(2*G9+F9-
2*D)+15*SIN(G9+F9+2
*D)+12*SIN(F9-2*D-
GS)-9*SIN(G9-F9-2*D
+GS)-8*SIN(F9+\GW)+8*
SIN(F9+2*D-GS)-7*
SIN(G9+F9-2*D+GS)+7
*SIN(G9+F9-GS)-7*
SIN(G9+F9-4*D)-6*
SIN(F9+GS)-6*SIN(3*
F9)+6*SIN(G9-F9-GS)
-5*SIN(F9+D)-5*SIN(
G9+F9+GS)-5*SIN(G9-
F9+GS)+5*SIN(F9-GS)
+5*SIN(F9-D)+4*SIN(
3*G9+F9)-4*SIN(F9-4
*D)-3*SIN(G9-F9-4*D
)+3*SIN(G9-3*F9)-2*
SIN(2*G9-F9-4*D)-2*
SIN(3*F9-2*D)+2*SIN
(2*G9-F9+2*D)+2*SIN
(G9-F9+2*D-GS)+2*
SIN(2*G9-F9-2*D)+2*
SIN(3*G9-F9)' '
60.36298-3.27746*
COS(G9)-.57994*COS(
G9-2*D)-.46357*COS(
2*D)-.08904*COS(2*
G9)+.03865*COS(2*G9
-2*D)-.03237*COS(2*
D-GS)-.02688*COS(G9
+2*D)-.02358*COS(G9
-2*D+GS)-.0203*COS(
G9-GS)+.01719*COS(D
)+.01671*COS(G9+GS)
+.01247*COS(G9-2*F9
)+.00704*COS(GS)+
.00529*COS(2*D+GS)-
.00524*COS(G9-4*D)+
.00398*COS(G9-2*D-
GS)-.00366*COS(3*G9
)-.00295*COS(2*G9-4
*D)-.00263*COS(D+GS
)+.00249*COS(3*G9-2
*D)-.00221*COS(G9+2
*D-GS)+.00185*COS(2
*F9-2*D)-.00161*COS
(2*D-2*GS)+.00147*
COS(G9+2*F9-2*D)-
.00142*COS(4*D)+
.00139*COS(2*G9-2*D
+GS)-.00118*COS(G9-
4*D+GS)-.00116*COS(
2*G9+2*D)-.0011*COS
(2*G9-GS)' }
\>>
CALS
{ '9*COS(3.9+
5507.55*p)+6*COS(
1.73+5223.69*p)' '
280*COS(3.199+
84334.662*p)+102*
COS(5.422+5507.553*
p)+80*COS(3.88+
5223.69*p)+44*COS(
3.7+2352.87*p)+32*
COS(4+1577.34*p)' '
6910*SIN(GS)+72*SIN
(2*GS)-17*T*SIN(GS)
-7*COS(GS-G4)+6*SIN
(L9-LS)+5*SIN(4*GS-
8*G3+3*G4)-5*COS(2*
GS-2*G2)-4*SIN(GS-
G2)+4*COS(4*GS-8*G3
+3*G4)+3*SIN(2*GS-2
*G2)-3*SIN(G4)-3*
SIN(2*GS-2*G4)' '
1.00014-.01675*COS(
GS)-.00014*COS(2*GS
)' }
CAL1
\<< { '84378*SIN(G1)+
10733*SIN(2*G1)+
1892*SIN(3*G1)-646*
SIN(2*F1)+381*SIN(4
*G1)-306*SIN(G1-2*
F1)-274*SIN(G1+2*F1
)-92*SIN(2*G1+2*F1)
+83*SIN(5*G1)-28*
SIN(3*G1+2*F1)+25*
SIN(2*G1-2*F1)+19*
SIN(6*G1)-9*SIN(4*
G1+2*F1)+8*T*SIN(G1
)+7*COS(2*G1-5*G2)' 
'24134*SIN(F1)+5180
*SIN(G1-F1)+4910*
SIN(G1+F1)+1124*SIN
(2*G1+F1)+271*SIN(3
*G1+F1)+132*SIN(2*
G1-F1)+67*SIN(4*G1+
F1)+18*SIN(3*G1-F1)
+17*SIN(5*G1+F1)-10
*SIN(3*F1)-9*SIN(G1
-3*F1)' '.39528-
.07834*COS(G1)-
.00795*COS(2*G1)-
.00121*COS(3*G1)-
.00022*COS(4*G1)' }
\>>
CAL2
\<< { '2814*SIN(G2)-
181*SIN(2*F2)-20*T*
SIN(G2)+12*SIN(2*G2
)-10*COS(2*GS-2*G2)
+7*COS(3*GS-3*G2)' 
'12215*SIN(F2)+83*
SIN(G2+F2)+83*SIN(
G2-F2)' '.72335-
.00493*COS(G2)' }
\>>
CAL4
\<< { '38451*SIN(G3)+
2238*SIN(2*G3)+181*
SIN(3*G3)-52*SIN(2*
F3)+37*T*SIN(G3)-22
*COS(G3-2*G4)-19*
SIN(G3-G4)+17*COS(
G3-G4)+17*SIN(4*G3)
-16*COS(2*G3-2*G4)+
13*COS(GS-2*G3)-10*
SIN(G3-2*F3)-10*SIN
(G3+2*F3)+7*COS(GS-
G3)-7*COS(2*GS-3*G3
)-5*SIN(G2-3*G3)-5*
SIN(GS-G3)-5*SIN(GS
-2*G3)-4*COS(2*GS-4
*G3)+4*T*SIN(2*G3)+
4*COS(G4)+3*COS(G2-
3*G3)+3*SIN(2*G3-2*
G4)' '6603*SIN(F3)+
622*SIN(G3-F3)+615*
SIN(G3+F3)+64*SIN(2
*G3+F3)' '1.53031-
.1417*COS(G3)-.0066
*COS(2*G3)-.00047*
COS(3*G3)' }
\>>
CAL5
\<< { '19934*SIN(G4)+
5023*T+2511+1093*
COS(2*G4-5*G5)+601*
SIN(2*G4)-479*SIN(2
*G4-5*G5)-185*SIN(2
*G4-2*G5)+137*SIN(3
*G4-5*G5)-131*SIN(
G4-2*G5)+79*COS(G4-
G5)-76*COS(2*G4-2*
G5)-74*T*COS(G4)+68
*T*SIN(G4)+66*COS(2
*G4-3*G5)+63*COS(3*
G4-5*G5)+53*COS(G4-
5*G5)+49*SIN(2*G4-3
*G5)-43*T*SIN(2*G4-
5*G5)-37*COS(G4)+25
*SIN(2*L4)+25*SIN(3
*G4)-23*SIN(G4-5*G5
)-19*T*COS(2*G4-5*
G5)+17*COS(2*G4-4*
G5)+17*COS(3*G4-3*
G5)-14*SIN(G4-G5)-
13*SIN(3*G4-4*G5)-9
*COS(2*L4)+9*COS(G5
)-9*SIN(G5)-9*SIN(3
*G4-2*G5)+9*SIN(4*
G4-5*G5)+9*SIN(2*G4
-6*G5+3*G6)-8*COS(4
*G4-10*G5)+7*COS(3*
G4-4*G5)-7*COS(G4-3
*G5)-7*SIN(4*G4-10*
G5)-7*SIN(G4-3*G5)+
6*COS(4*G4-5*G5)-6*
SIN(3*G4-3*G5)+5*
COS(2*G5)-4*SIN(4*
G4-4*G5)-4*COS(3*G5
)+4*COS(2*G4-G5)-4*
COS(3*G4-2*G5)-4*T*
COS(2*G4)+3*T*SIN(2
*G4)+3*COS(5*G5)+3*
COS(5*G4-10*G5)+3*
SIN(2*G5)-2*SIN(2*
L4-G4)+2*SIN(2*L4+
G4)-2*T*SIN(3*G4-5*
G5)-2*T*SIN(G4-5*G5
)' '-4692*COS(G4)+
259*SIN(G4)+227-227
*COS(2*G4)+30*T*SIN
(G4)+21*T*COS(G4)+
16*SIN(3*G4-5*G5)-
13*SIN(G4-5*G5)-12*
COS(3*G4)+12*SIN(2*
G4)+7*COS(3*G4-5*G5
)-5*COS(G4-5*G5)' '
5.20883-.25122*COS(
G4)-.00604*COS(2*G4
)+.0026*COS(2*G4-2*
G5)-.0017*COS(3*G4-
5*G5)-.00106*SIN(2*
G4-2*G5)-.00091*T*
SIN(G4)-.00084*T*
COS(G4)+.00069*SIN(
2*G4-3*G5)-.00067*
SIN(G4-5*G5)+.00066
*SIN(3*G4-5*G5)+
.00063*SIN(G4-G5)-
.00051*COS(2*G4-3*
G5)-.00046*SIN(G4)-
.00029*COS(G4-5*G5)
+.00027*COS(G4-2*G5
)-.00022*COS(3*G4)-
.00021*SIN(2*G4-5*
G5)' }
\>>
CAL6
\<< { '23045*SIN(
G5)+5014*T-2689*COS
(2*G4-5*G5)+2507+
1177*SIN(2*G4-5*G5)
-826*COS(2*G4-4*G5)
+802*SIN(2*G5)+425*
SIN(G4-2*G5)-229*T*
COS(G5)-153*COS(2*
G4-6*G5)-142*T*SIN(
G5)-114*COS(G5)+101
*T*SIN(2*G4-5*G5)-
70*COS(2*L5)+67*SIN
(2*L5)+66*SIN(2*G4-
6*G5)+60*T*COS(2*G4
-5*G5)+41*SIN(G4-3*
G5)+39*SIN(3*G5)+31
*SIN(G4-G5)+31*SIN(
2*G4-2*G5)-29*COS(2
*G4-3*G5)-28*SIN(2*
G4-6*G5+3*G6)+28*
COS(G4-3*G5)+22*T*
SIN(2*G4-4*G5)-22*
SIN(G5-3*G6)+20*SIN
(2*G4-3*G5)+20*COS(
4*G4-10*G5)+19*COS(
2*G5-3*G6)+19*SIN(4
*G4-10*G5)-17*T*COS
(2*G5)-16*COS(G5-3*
G6)-12*SIN(2*G4-4*
G5)+12*COS(G4)-12*
SIN(2*G5-2*G6)-11*T
*SIN(2*G5)-11*COS(2
*G4-7*G5)+10*SIN(2*
G5-3*G6)+10*COS(2*
G4-2*G5)+9*SIN(4*G4
-9*G5)-8*SIN(G5-2*
G6)-8*COS(2*L5+G5)+
8*COS(2*L5-G5)+8*
COS(G5-G6)-8*SIN(2*
L5-G5)+7*SIN(2*L5+
G5)-7*COS(G4-2*G5)-
7*COS(2*G5)-6*T*SIN
(4*G4-10*G5)+6*T*
COS(4*G4-10*G5)+6*T
*SIN(2*G4-6*G5)-5*
SIN(3*G4-7*G5)-5*
COS(3*G4-3*G5)-5*
COS(2*G5-2*G6)+5*
SIN(3*G4-4*G5)+5*
SIN(2*G4-7*G5)+4*
SIN(3*G4-3*G5)+4*
SIN(3*G4-5*G5)+4*T*
COS(G4-2*G5)+3*T*
COS(2*G4-4*G5)+3*
COS(2*G4-6*G5+3*G6)
-3*T*SIN(2*L5)+3*T*
COS(2*G4-6*G5)-3*T*
COS(2*L5)+3*COS(3*
G4-7*G5)+3*COS(4*G4
-9*G5)+3*SIN(3*G4-6
*G5)+3*SIN(2*G4-G5)
+3*SIN(G4-4*G5)+2*
COS(3*G5-3*G6)+2*T*
SIN(G4-2*G5)+2*SIN(
4*G5)-2*COS(3*G4-4*
G5)-2*COS(2*G4-G5)-
2*SIN(2*G4-7*G5)+2*
COS(G4-4*G5)+2*COS(
4*G4-11*G5)-2*SIN(
G5-G6)' '8297*SIN(
G5)-3346*COS(G5)+
462*SIN(2*G5)-189*
COS(2*G5)+185+79*T*
COS(G5)-71*COS(2*G4
-4*G5)+46*SIN(2*G4-
6*G5)-45*COS(2*G4-6
*G5)+29*SIN(3*G5)-
20*COS(2*G4-3*G5)+
18*T*SIN(G5)-14*COS
(2*G4-5*G5)-11*COS(
3*G5)-10*T+9*SIN(G4
-3*G5)+8*SIN(G4-G5)
-6*SIN(2*G4-3*G5)+5
*SIN(2*G4-7*G5)-5*
COS(2*G4-7*G5)+4*
SIN(2*G4-5*G5)-4*T*
SIN(2*G5)-3*COS(G4-
G5)+3*COS(G4-3*G5)+
3*T*SIN(2*G4-4*G5)+
3*SIN(G4-2*G5)+2*
SIN(4*G5)-2*COS(2*
G4-2*G5)' '9.55774-
.53252*COS(G5)-
.01878*SIN(2*G4-4*
G5)-.01482*COS(2*G5
)+.00817*SIN(G4-G5)
-.00539*COS(G4-2*G5
)-.00524*T*SIN(G5)+
.00349*SIN(2*G4-5*
G5)+.00347*SIN(2*G4
-6*G5)+.00328*T*COS
(G5)-.00225*SIN(G5)
+.00149*COS(2*G4-6*
G5)-.00126*COS(2*G4
-2*G5)+.00104*COS(
G4-G5)+.00101*COS(2
*G4-5*G5)+.00098*
COS(G4-3*G5)-.00073
*COS(2*G4-3*G5)-
.00062*COS(3*G5)+
.00042*SIN(2*G5-3*
G6)+.00041*SIN(2*G4
-2*G5)-.0004*SIN(G4
-3*G5)+.0004*COS(2*
G4-4*G5)-.00028*T-
.00023*SIN(G4)+
.0002*SIN(2*G4-7*G5
)' }
\>>
CAL7
\<< { '19397*SIN(G6)+
570*SIN(2*G6)-536*T
*COS(G6)+143*SIN(G5
-2*G6)+110*T*SIN(G6
)+102*SIN(G5-3*G6)+
76*COS(G5-3*G6)-49*
SIN(G4-G6)+64*T-30*
T*COS(2*G6)+29*SIN(
2*G4-6*G5+3*G6)+29*
COS(2*G6-2*G7)-28*
COS(G6-G7)+23*SIN(3
*G6)-21*COS(G4-G6)+
20*SIN(G6-G7)+20*
COS(G5-2*G6)-19*COS
(G5-G6)+17*SIN(2*G6
-3*G7)+14*SIN(3*G6-
3*G7)+13*SIN(G5-G6)
-24*T*COS(G6)-12*
COS(G6)+10*SIN(2*G6
-2*G7)-9*SIN(2*F6)-
18*T*SIN(G6)+9*COS(
2*G6-3*G7)+8*T*COS(
G5-2*G6)+7*T*COS(G5
-3*G6)-7*T*SIN(G5-3
*G6)+7*T*SIN(2*G6)+
6*SIN(2*G4-6*G5+2*
G6)+6*COS(2*G4-6*G5
+2*G6)+5*SIN(G5-4*
G6)-4*SIN(3*G6-4*G7
)+4*COS(3*G6-3*G7)-
3*COS(G7)-2*SIN(G7)
' '2775*SIN(F6)+131
*SIN(G6-F6)+130*SIN
(G6+F6)' '19.21216-
.90154*COS(G6)-
.02488*T*SIN(G6)-
.02121*COS(2*G6)-
.00585*COS(G5-2*G6)
-.00508*T*COS(G6)-
.00451*COS(G4-G6)+
.00336*SIN(G5-G6)+
.00198*SIN(G4-G6)+
.00118*COS(G5-3*G6)
+.00107*SIN(G5-2*G6
)-.00103*T*SIN(2*G6
)-.00081*COS(3*G6-3
*G7)' }
\>>
CAL8
\<< { '3523*SIN(
G7)-50*SIN(2*F7)-43
*T*COS(G7)+29*SIN(
G4-G7)+19*SIN(2*G7)
-18*COS(G4-G7)+13*
COS(G5-G7)+13*SIN(
G5-G7)-9*SIN(2*G6-3
*G7)+9*COS(2*G6-2*
G7)-5*COS(2*G6-3*G7
)-4*T*SIN(G7)+4*COS
(G6-2*G7)+8*T*SIN(
G7)' '6404*SIN(F7)+
55*SIN(G7+F7)+55*
SIN(G7-F7)-33*T*SIN
(F7)' '30.07175-
.25701*COS(G7)-
.00787*COS(2*L6-G6-
2*L7)+.00409*COS(G4
-G7)-.00314*T*SIN(
G7)+.0025*SIN(G4-G7
)-.00194*SIN(G5-G7)
+.00185*COS(G5-G7)'
}
\>>
CAL9
\<< { '101577*SIN(G8)
+15517*SIN(2*G8)-
3593*SIN(2*F8)+3414
*SIN(3*G8)-2201*SIN
(G8-2*F8)-1871*SIN(
G8+2*F8)+839*SIN(4*
G8)-757*SIN(2*G8+2*
F8)-285*SIN(3*G8+2*
F8)+454*T*SIN(G8)+
218*SIN(2*G8-2*F8)+
200*T*SIN(G8)' '
57726*SIN(F8)+15257
*SIN(G8-F8)+14102*
SIN(G8+F8)+3870*SIN
(2*G8+F8)+1138*SIN(
3*G8+F8)+472*SIN(2*
G8-F8)+353*SIN(4*G8
+F8)-144*SIN(G8-3*
F8)-119*SIN(3*F8)-
111*SIN(G8+3*F8)' '
40.74638-9.58235*
COS(G8)-1.16703*COS
(2*G8)-.22649*COS(3
*G8)-.04996*COS(4*
G8)' }
\>>
SDAT
{ { 345.31156524
-59.3781705 26 -.16
.46 } { 69.78901344
-5.4674392 21 1.54
.85 } { 76.8297184
-31.1228063 280
-.03 .12 } {
81.8577415
22.8643432 13 .8
.08 } { 88.75414772
-16.0268472 95 1.85
.5 } { 104.9603567
-75.8237834 360 .15
-.72 } {
104.0815749
-39.6052509 2.7 .01
-1.46 } {
115.785452
-16.0196217 3.5 .42
.38 } { 113.2154745
6.684069 11 1 1.14
} { 149.8287058
-.46469231 26 -.11
1.35 } { 221.86971
-52.87803 110 .1
1.41 } {
221.64572335
-48.63873204 130
-.23 1.25 } {
203.8410821
-2.0546734 79 -.23
.98 } { 233.7920649
-44.1374373 140
-.24 .61 } {
204.2332698
30.73620812 11 1.23
-.04 } { 239.479783
-42.594071 1.3 .68
0 } { 249.7616937
-4.56997863 100
1.83 .96 } {
285.3154391
61.7328474 8.1 0
.03 } { 301.775503
29.3036472 5.1 .22
.77 } { 335.3285843
59.9062706 560 .09
1.25 } {
333.8597432
-21.13538399 6.7
.09 1.16 } }
DAMO
{ "Sun " "Mon "
"Tue " "Wed "
"Thu " "Fri "
"Sat " "Sun" "Jan "
"Feb " "Mar "
"Apr " "May "
"Jun " "Jul "
"Aug " "Sep "
"Oct " "Nov "
"Dec " }
NM
{ "Mercury" "Venus"
"Mars" "Jupiter"
"Saturn" "Uranus"
"Neptune" "Pluto"
"Moon" "Sun"
"\Ga Eri" "\Ga Tau"
"\Gb Ori" "\Ga Aur"
"\Ga Ori" "\Ga Car"
"\Ga CMa" "\Ga CMi"
"\Gb Gem" "\Ga Leo"
"\Ga Cru" "\Gb Cru"
"\Ga Vir" "\Gb Cen"
"\Ga Boo" "\Ga Cen"
"\Ga Sco" "\Ga Lyr"
"\Ga Aql" "\Ga Gyg"
"\Ga PsA" }
NEWS
\<<
"Type a Star's number ?"
":No:" INPUT OBJ\->
'n' STO
  IF n 21 >
  THEN CLLCD
"Uncompanionable star"
1 DISP 3 FREEZE
  ELSE CLLCD NM n
10 + GET 1 DISP 3
FREEZE
  END
\>>
NOVA
\<< STD JG "  DST= "
DL + + "
TZ= " TZ
+ "  LT= " LT \->HMS
+ + + "
JD0 = " JD0
+ + "
JD  = " JD +
+ "
UT= " UT + +
"
" DT "  " DN + +
+ + "
\Gl: " \GlM + +
"  \O/: " \O/ + + CLLCD
1 DISP 3 FREEZE
\>>
WIPE
{ t C ST GST T G4
G3 G2 GS LS L9 \GW p
r \Gl \Gb \GlS \GbS SD ET V
BV \Ga \Gd n A a RI SE
R PPAR DN }
ZZ
\<< + 1 \->GROB GOR
\>>
F24
\<< DUP 24 / IP 24 *
-
  IF DUP 0 <
  THEN 24 +
  END
\>>
F36
\<< DUP 360 / IP 360
* -
  IF DUP 0 <
  THEN 360 +
  END
\>>
\GD\165
.0016
\GD\Ge
.0001
\GlM
6
\O/
7
\Ge
23
JD0
4
JD
5
JG
"Greetings "
UT
"Tyko v30 1992"
DT
"    by Kati Sinenmaa"
DL
1
LT
3
TZ
2

END_RPL