🚀 go-pugleaf

llew@wpi.WPI.EDU (Lew Yan Voon) writes
>does anyone know how to draw a coil using latex?

The following METAFONT code let
you draw horizontally laid coils.
Each character corresponds to one turn or an end of a coil.
Please ask someone near you about how to install/use it.

Hideki Isozaki,       NTT Basic Research Labs.

-------------------- spring.mf --------------------
mode_setup;

numeric code; numeric pitch;

for code:=0 upto 6:

pitch:=code*1pt#+4pt#;

beginchar(4code,pitch,5pt#,5pt#);
path p;
p=(0,-d){right}..(.8w,.3h){up}..(.5w,h){left}..(.2w,.3h){down}..{right}(w,-d);
pickup pencircle scaled 0.4pt;
draw p; 
pickup pencircle scaled 2.5pt;
undraw subpath(3.2,3.8) of p;
pickup pencircle scaled 0.4pt;
draw subpath(3,4) of p;
endchar;

beginchar(4code+1,pitch,5pt#,5pt#);
path p;
p=(0,-d){right}..(.8w,.3h){up}..(.5w,h){left}..(.2w,.3h){down}..{right}(w,-d);
pickup pencircle scaled 0.4pt;
draw p; 
pickup pencircle scaled 2.5pt;
undraw subpath(0.2,0.8) of p;
pickup pencircle scaled 0.4pt;
draw subpath(0,1) of p;
endchar;

beginchar(4code+2,pitch,5pt#,5pt#);
pickup pencircle scaled 0.4pt;
draw (w,-d){left}..(.3w,0)---(0,0);
endchar;

beginchar(4code+3,pitch,5pt#,5pt#);
pickup pencircle scaled 0.4pt;
draw (0,-d){right}..(.7w,0)---(w,0);
endchar;

endfor;

end