🚀 go-pugleaf

                   UND ES FUNKTIONIERT DOCH.
		   -------------------------

              MIT DEM AMIGA UeBER T-ONLINE INS INTERNET.
	      ------------------------------------------


Als Zugang wird der Slip-Zugang von T-Online Verwendet.

Einzelheiten stehen in den folgenden Zeitschriften.

   Ct     1995  Heft 12 Seite 324ff
   COM    1/96 Seite 30ff  und   COM 3/96 Seite 49.


Als cslip.device muss das cslip.device Ver. 37.4 verwendet werden.
Zu finden im Aminet oder auf der AminetCD Nr.4 als 
comm/net/cslip_sana2.lha.

Die neueren rhcslip.device funktionieren NICHT.
----------------------------------------------


Ich habe das ganze mit AmiTCP V.2.2 und AmiTCP 4.0Demo getestet.


Als Dialer wurde IPDial Ver.1.9 von Jochen Wiedmann verwendet.
Zu finden im Aminet oder auf der AminetCD Nr.10 als 
comm/tcp/IPDialv19.lha.


Doch hier nun das Startscript fuer AmiTCP  4.0 DEMO
---------------------------------------------------

Als Nameserver (AmiTCP:db/resolv.conf) sollte die Adresse 194.25.2.129 
eingetragen sein.
Als Domain (AmiTCP:db/resolv.conf) sollte btx.dtag.de eingetragen sein.



----------------------Start AmiTCP    Beginn----------------------------


;BEGIN AmiTCP/IP
Assign AmiTCP: HardDisk_1:amtcp4
Path AmiTCP:bin add
Mount APIPE: from AmiTCP:devs/APipe-Mountlist
;END AmiTCP/IP
; log in
echo
echo login: MY_LOGIN
AmiTCP:bin/login -f MY_LOGIN
AmiTCP:bin/umask 022
AmiTCP:AmiTCP
WaitForPort AMITCP
; Configure loop-back device
AmiTCP:bin/ifconfig lo0 localhost
; DIAL to t-online use script amitcp:Login.IDial
IPDial AmiTCP:Login.IPDial ECHO VERBOSE
; Create cslip0 configuration file
echo serial.device 0 2400 $MYIP >ENV:Sana2/slip0.config
; Configure cslip0
AmiTCP:bin/ifconfig cslip0 $MYIP $DESTIP netmask 255.255.255.254
; Add route to this host
AmiTCP:bin/route add $MYIP localhost
; Add route to the default gateway
AmiTCP:bin/route add default $DESTIP
Mount TCP: from AmiTCP:devs/Inet-Mountlist
; Start the internet `super server'
run AmiTCP:bin/inetd

---------------------Start AmiTCP     END-------------------------------





In der Datei AmiTCP:db/Interfaces muss die Zeile cslip0 abgeaendert 
werden.

  cslip0 DEV=DEVS:Networks/cslip.device UNIT=0





Und hier das Loginscript fuer IPDial
------------------------------------

-------------------- Login-Scrip IPDial fuer T-Online ------------------

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;
;
;   Login script for AmiTCP/SLIP connection to the Internet via
;   T-Online. Germany using IPDial
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;
;
;   The line below *must* be present and *must* be the first command
;   line in the script. It specifies the device and the protocol to
;   use. (Possible protocols are 7WIRE (= RTSCTS), XONXOFF or NONE.)
;   You may omit the protocol, in which case the defaults of the
;   serial.device are used.
;
;   Be sure, that the parameters you are using in this script are the
;   same as used for initializing AmiTCP/IP!

    DEVICE serial.device NONE UNIT 0


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;
;
;   Certain settings (Note, that these override the respective settings
;   of the serial.prefs.)
;
;   Possible settings are:
;       BAUD            Baudrate, integer
;       DATABITS        number of data bits, integer
;       STOPBITS        number of stop bits, integer
;       BUFSIZE         Read buffer size, integer
;       PARITY          one of NONE, ODD or EVEN
;
;   These are scanned with ReadArgs(), thus you can either use the syntax
;       set BAUD=38400
;   or, if you prefer, this version
;       set BAUD 38400
;   In the first case, however, it is important, that you omit blanks.
;
; 
------------------------------------------------------------------------
, ----------- Hier bei BAUD die verwendete BAUD-Rate einsetzen 
-----------

    set BAUD=2400 DATABITS=8 STOPBITS=1 BUFSIZE=4096

; 
------------------------------------------------------------------------
; 
------------------------------------------------------------------------


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;
;
;   Show the new settings

;   SHOWPARMS


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;
;
;   Send initialization command
; Datencompression und Flusscontrolle am Modem ausschalten.

    SEND "AT\\N1%C0\r"


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;
;
;   Wait for the modems ok; break, if timeout

    WAIT TIMEOUT=10 "NO CARRIER" "OK"
    ON STATUS GOTO TIMEOUT NoCarrier


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;
;
;   Initialize the modem not to hang up, when IPDial terminates (this
;   will make DTR becoming low)

    SEND "AT&D0\r"


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;
;
;   Wait for the modems ok; break, if timeout

    WAIT TIMEOUT=10 "OK"
    ON STATUS GOTO TIMEOUT


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;
;
;   Dialing ...

Dial:
    SEND "ATDP01910\r"

    WAIT TIMEOUT=60 "CONNECT"
    ON STATUS GOTO TIMEOUT Login



;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;
;
;   The usual case: Our Remote is busy. :-(
;   We do a delay of 30 secs (thanks, telecom :-) and dial again.

    Echo "Remote busy, delaying ...\n"
    DELAY 30
    Echo "Trying again.\n"
    GOTO Dial


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;
;
;   Okay, we are connected. Login into the host. It is a local
;   convention that we have to enter the password twice.

Login:
    DELAY 5
    SEND ".\r"
    DELAY 4
    WAIT TIMEOUT=10 "ennung"
    DELAY 2
;Anschlusskennung senden
; XXXXXXXXXXX durch Anschlusskennung ersetzen.
    SEND "XXXXXXXXXXXX"
    DELAY 2
    SEND "\r"
; Warten auf Passwort eingabe und Passwort senden
    WAIT TIMEOUT=10 "[?25h"
    SEND "XXXXXXXX"           ; XXXXXXXXXX durch Passwort ersetzen
; Datenvorwarnung ausschalten
    WAIT TIMEOUT=10 "[?25h"
    SEND "**53#"
; Internet-Gateway aufrufen
    WAIT TIMEOUT=10 "[?25h"
    DELAY 1
    SEND "**190144100#"
; Zeittakt bestaetigen
    WAIT TIMEOUT=10 "DM/Min"
    SEND "19"
; IP-Adressen abfragen
    WAIT TIMEOUT=10 "STATUS OK"
    SEND "L"
    SEND "I"
    SEND "N"
    SEND "\r"
    WAIT TIMEOUT=10 "YOURIP"
    DELAY 2

;   If we came so far, everything is fine. AmiTCP (and thus Slip) may be
;   started.
;
;   Remote host will answer with a string like
;
;       YOURIP 194.25.3.113
;
;   Scan this and store the values into the environment variables

    SCAN "%{YOURIP%} %[MYIP%%" GLOBAL SAVE
    SCAN "%{DESTIP%} %[DESTIP%%" GLOBAL SAVE
    SCAN "%{HOSTNAME%} %[HOSTNAME%%" GLOBAL SAVE

    SEND "OK\r"

    ECHO "CSlip connection ready, starting AmiTCP/Ip.\n"
    EXIT 0


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;
;
;   Error message: Timeout

TIMEOUT:
    ECHO "\nTimeout\n"
    EXIT 10

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;
;
;   Error message: NO CARRIER

NoCarrier:
    ECHO "\nNO CARRIER\n"
    EXIT 10

-----------------------IPDial Login  END 
------------------------------------


Viel Spass im Internet.