🚀 go-pugleaf

Hi y'all.

I hope you are all well, and indeed there.  :)

For the last 28 hours I have been unable to connect to Demon for more than
about five seconds. As you may recall, I'm fairly clueless - but I've
found that commenting out part of Sir Phil Soke's Link script from the
AmiTCP Demon installation has just about got me on-line....

What led me to do this were comments in the link window about "resolve
failing"

Anyway, I expect Demon or BT or both have changed something or other which
is causing a problem.

The stinking pc in the other room is connecting okay, btw, but is not
used for e-mail or news.

Here is the ammended Link script. Any thoughts on the implications of the
section I have commented out (nearly halfway down) that _seems_ to make
all the difference.

As ever, very grateful for any help, general comments or expressions of
sympathy.    :)


/*rx
 * AmiTCP DIS v4 Amiga Installation
 * ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 *
 * NAME
 *   link -- Control the state of the AmiTCP connection
 * USAGE
 *   link up|down [news|autonews|automail]
 * PURPOSE
 *   This script makes using AmiTCP on a dialup to Demon much easier. You
 *   can connect/disconnect by entering LINK UP or LINK DOWN.
 *
 * 07/02/96 - Philip Stokes <phil@stokes.demon.co.uk>
 *          - fixed bug in 'route delete' command, wrong IP address was
 *            given.
 *          - Added DropLink() function to avoid recursion of original
 *            version (Link called itself to close the connection)
 */

if ~exists('libs:rexxsupport.library') then
do
  say 'Cannot find rexxsupport.library, aborting..'
   exit
end

if ~show('L','rexxsupport.library') then
do
  addlib('rexxsupport.library',0,-30,0)
end
   say 'Hi Angus'
CALL PRAGMA('priority',3)

/* VARIABLES - Modify these for your setup */
mynode = "angusm"                           /* PUT YOUR NODE NAME HERE */
fingercmd = "AmiTCP:bin/finger"
mailhost = "@post.demon.co.uk"
DISmail = 1
THISmail = 1

address command
arg which news

/* THE SCRIPT PROPER */

if which='' then
do
   say ''
   say 'Usage: Link Up|Down [News|Autonews|Automail]'
   say ''
   exit
end

if which~='UP' & which~='DOWN' then
do
   say ''
   say 'Invalid command: ' || which || ' - try Up or Down'
   say ''
   exit
end

if news~='NEWS' & news~='AUTONEWS' & news~='AUTOMAIL' & news~='' then
do
   say 'Invalid parameter: ' || news || ' - try News, Autonews or Automail'
end
else
do
   if which='UP' then
   do
      'AmiTCP:bin/online ppp0'
      if RC=10 then do
         say ''
         say 'Connection/Dial Error'
         exit
      end
      'AmiTCP:bin/ifconfig lo0 localhost'
      'AmiTCP:bin/ifconfig ppp0 $ppp0IPLocal $ppp0IPRemote'
      'AmiTCP:bin/route add default $ppp0IPRemote'
      if ~open(log,'uuspool:link.log','A') then
      do
         if open(log,'uuspool:link.log','W') then
         do
            call WriteLog('Connection Opened')
         end
      end
      else
      do
         call WriteLog('Connection Opened')
      end

/*      'resolve >NIL: 158.152.1.65'
 *      if RC>=10 then do
 *         say ''
 *         say 'Connection not established'
 *         call DropLink()
 *         exit
 */      end

      'AmiTCP:bin/mailkick post.demon.co.uk handletos logsends'
      if exists('AmiTCP:db/LinkMacro') then
      do
         'execute AmiTCP:db/LinkMacro'
      end
      if news='NEWS' then
      do
         say 'Pulling news...'
         'execute AmiTCP:bin/nntptransfer mode news'
      end
      if news='AUTONEWS' then
      do
         say 'Slurping news with auto link down...'
         'execute AmiTCP:bin/nntptransfer mode news'
         do while DISmail = 1 | THISmail = 1
            call checkDISmail
            call checkTHISmail
         end
         'wait 5'
         call DropLink()
      end
      if news='AUTOMAIL' then
      do
         do while DISmail = 1 | THISmail = 1
            call checkDISmail
            call checkTHISmail
         end
         'wait 5'
         call DropLink()
      end
   end
   else
   do
      if which='DOWN' then
      do
         call DropLink()
      end
   end
end
exit

/* -------------------------- */
DropLink:

do
   'AmiTCP:bin/mailkick quit'
   'AmiTCP:bin/ifconfig ppp0 down'
   'AmiTCP:bin/offline ppp0'
   'AmiTCP:bin/route delete $ppp0IPRemote'
   'AmiTCP:bin/route delete default'
   if ~open(log,'uuspool:link.log','A') then
   do
      if open(log,'uuspool:link.log','W') then
      do
         call WriteLog('Connection Closed')
      end
   end
   else
   do
      call WriteLog('Connection Closed')
   end
end
return

/* -------------------------- */
checkDISmail:

say "Checking for incoming mail..."
DISmail = 0
fingercmd mynode || mailhost ">t:linktmp"
if (exists('t:linktmp')>0) then
do
   result = open('fingerout', 't:linktmp', read)
   do while ~eof('fingerout')
      ln = readln('fingerout')
      ln = strip(ln)
      if index(ln,'[')=0 & index(ln,']')=0 & ln~='' then
      do
         if find(ln,'no')=0 then
         do
            DISmail = 1
         end
      end
   end
   result = close('fingerout')
   result = delete('t:linktmp')
end
if DISmail = 1 then
do
   say "Found incoming mail, waiting..."
   "wait 5"
end
else
do
   say "No incoming mail."
end
return

/* -------------------------- */
checkTHISmail:

say "Checking for outgoing mail..."
THISmail = 0
"list nohead uuspool: >t:spooltmp"
if (exists('t:spooltmp')>0) then
do
   result = open('spoolout', 't:spooltmp', read)
   do while ~eof('spoolout')
      ln = readln('spoolout')
      ln = strip(ln)
      if index(ln,'C.')~=0 | index(ln,'D.')~=0 |index(ln,'X.')~=0 then
      do
         THISmail = 1
      end
   end
   result = close('spoolout')
   result = delete('t:spooltmp')
end
if THISmail = 1 then
do
   say "Found outgoing mail, waiting..."
   "wait 5"
end
else
do
   say "No outgoing mail."
end
return

/* -------------------------- */
WriteLog: procedure EXPOSE mynode

logmsg = Arg(1)
logline = Date(E) || '-' || Time() || ' ' || mynode || ' ' || logmsg
call writeln(log,logline)
call close(log)
return

/* EOF */



                  All the best,
                        Angus Manwaring.       (for e-mail remove ANTISPEM)

I need your memories for the Amiga Games Database: A collection of Amiga
Game reviews by Amiga players http://www.angusm.demon.co.uk/AGDB/AGDB.html