🚀 go-pugleaf

Den 20-01-2013 19:24, Morten Christensen skrev:
> På min server med Ubuntu 10.04 har jeg en simpel csv-fil med dato, klokkeslet og værdi:
> 
> 2013-01-09;00:00;16.8
> 2013-01-10;00:00;14.0
 ......

> Der kommer en png-fil ud af det, men der er ingen data i den.
> 
> 
> Kan nogen af jer sige, om det er muligt, og hvordan scriptet skal se ud ?

ja dit problem er at datoer ikke er tal, og du skal passe på datoer i
x-range er indenfor graf, for ellers plottes udenfor !!


så enten 1) lav datoer om til tal
eller 2) se på
   http://psy.swansea.ac.uk/staff/carter/gnuplot/gnuplot_time.htm


så:
..........
#!/usr/bin/gnuplot
set terminal png
set datafile separator ";"
set title "Dagsforbrug de sidste 11 dage"
set ylabel "m3 i alt pr. dag"
set xlabel "dag"

# sakset fra
#  http://psy.swansea.ac.uk/staff/carter/gnuplot/gnuplot_time.htm
# Setting xdata to time precludes the use of histograms.
set xdata time
set timefmt "%Y-%m-%d"

# set format x controls the way that gnuplot displays the dates on the x axis.
# "%Y-%m-%d" is the same as "%F", but "%F" applies to output only; it won't work
# for timefmt, which controls data reading.
set format x "%Y-%m-%d"

# out draws the tic marks on the outside of the border; otherwise they'd be
# obscured by the boxes.
set xtics rotate by 90 offset 0,-4 out nomirror

set yrange [10:20]
set output 'liste2.png'

plot "liste.csv" using 1:3 with lines
#.........