🚀 go-pugleaf

> 文字列を空白で分割したいのですが、
> 空白を "" や \ でクオートやエスケープができる方法を探しています。

以下のように while で1文字ずつループすることにしました。
どうもありがとうございました。

(defun split-string-shell-quote (str)
  (let ((pos 0) (len (length str)) (state 'out-word)
	char-list str-list char blankp)
    (while (< pos len)
      (setq char (aref str pos))
      (setq blankp (memq char '(?  ?\t ?\n)))
      (cond
       ((and (eq state 'out-word) blankp)) ; skip blank
       ((and (eq state 'in-word) blankp) ; end word
	(setq str-list
	      (cons (concat (nreverse char-list)) str-list))
	(setq char-list nil state 'out-word))
       ((eq state char) 		; break out ' or "
	(setq state 'in-word))
       ((and (or (eq state 'in-word) (eq state 'out-word)) ; into ' or "
	     (or (eq char ?') (eq char ?\")))
	(setq state char))
       (t				; add char to char-list
	(when (eq char ?\\)
	  (setq pos (1+ pos))
	  (setq char (aref str pos)))
	(when (eq state 'out-word)
	  (setq state 'in-word))
	(setq char-list (cons char char-list))))
      (setq pos (1+ pos)))
    (cond ((memq state '(?' ?\"))
	   (error "Missing %c" state))
	  ((eq state 'in-word)
	   (setq str-list
		 (cons (concat (nreverse char-list)) str-list))))
    (nreverse str-list)))


関係ないけど、concat は引数0個でもいいけど、

(concat)
=>""

string はだめなんですね。

(string)
=>(wrong-number-of-arguments #<subr string> 0)

ちょっと不便。

---
藤井宏憲