🚀 go-pugleaf

>>>>> "Maxime" == Maxime MORGE <morge@simade.emse.fr> writes:
> je r�dige un article en LaTeX via Emacs. Cet article doit contenir moins
> de 2000 mots. j'aimerais donc disposer d'un outil me permettant d'estimer
> la taille de cet article. Id�alement, une fonction Lisp prennant en
> compte le formatage LaTeX pourrait convenir. Toutefois tout autre
> type de solution m'int�resse. Quelque chose me dit que je ne suis pas le
> seul � avoir �t� confront� � ce probl�me.

Je suis s�r que qqun � mieux � proposer, mais j'utilise le code simpliste
ci-dessous (il sera d'ailleurs inclu dans Emacs-21).  Il compte tous les
mots de 2 lettres et plus, sauf les commandes TeX (et il ne compte pas les
mots pass�s comme arguments � certaines commandes).  �a signifie
malheureusement qu'il compte aussi les mots qui sont dans les commentaires.


	Stefan


(defconst tex-discount-args-cmds
  '("begin" "end" "input" "special" "cite" "ref" "include" "includeonly"
    "documentclass" "usepackage" "label")
  "TeX commands whose arguments should not be counted as text.")

(defun tex-count-words (begin end)
  "Count the number of words in the buffer."
  (interactive
   (if (and transient-mark-mode mark-active)
       (list (region-beginning) (region-end))
     (list (point-min) (point-max))))
  ;; TODO: skip comments and math and maybe some environments.
  (save-excursion
    (goto-char begin)
    (let ((count 0))
      (while (and (< (point) end) (re-search-forward "\\<" end t))
	(if (not (eq (char-syntax (preceding-char)) ?/))
	    (progn
	      ;; Don't count single-char words.
	      (unless (looking-at ".\\>") (incf count))
	      (forward-char 1))
	  (let ((cmd
		 (buffer-substring-no-properties
		  (point) (progn (when (zerop (skip-chars-forward "a-zA-Z@"))
				   (forward-char 1))
				 (point)))))
	    (when (member cmd tex-discount-args-cmds)
	      (skip-chars-forward "*")
	      (forward-comment (point-max))
	      (when (looking-at "\\[")
		(forward-sexp 1)
		(forward-comment (point-max)))
	      (if (not (looking-at "{"))
		  (forward-char 1)
		(forward-sexp 1))))))
      (message "%s words" count))))