🚀 go-pugleaf

  [ X-Post f.c.t.xml f.c.a.emacs, Fu2 not fixed ]

nicolas // <akuma@swing.be> writes:

> Je fais partie des "autres", et j'utilise vim. � ce propos, les
> plug-ins xml de vim manquent � mes yeux d'une fonctionnalit�
> importante pour qui travaille comme moi sur du texte annot�
> (linguistique de corpus): celle de pouvoir cacher les balises. Je ne
> parle pas de repli, mais d'effacement temporaire des tags. Je ne
> sais pas si emacs le propose. Si c'est le cas, il se peut r�ellement
> que je bascule dans l'autre monde (celui d'emacs).

  Ceci pourrait t'int�resser :

    (defvar nico:hided-tags nil
      "...")

    (make-variable-buffer-local 'nico:hided-tags)

    (defun nico:toggle-hiding-tags ()
      (interactive)
      (if nico:hided-tags
          (let (end (beg (point-min)))
            (unless (get-text-property beg 'nico:hided-tag)
              (setq beg (next-single-property-change beg 'nico:hided-tag)))
            (while (setq end (next-single-property-change beg 'nico:hided-tag))
              (message "DEBUG: Make visible from %S to %S" beg end)
              (put-text-property beg end 'invisible nil)
              (put-text-property beg end 'nico:hided-tag nil)
              (setq beg end))
            (setq nico:hided-tags nil))
        (save-excursion
          (goto-char (point-min))
          (let (type (p (point)))
            (while (setq type (xmltok-forward))
              (when (memq type '(start-tag end-tag empty-element))
                (message "DEBUG: Hiding from %S to %S" p (point))
                (put-text-property p (point) 'invisible t)
                (put-text-property p (point) 'nico:hided-tag t))
              (setq p (point)))
            (setq nico:hided-tags t)))))

    (eval-after-load 'nxml-mode
      '(define-key nxml-mode-map (kbd "<f12>") 'nico:toggle-hiding-tags))

  Lorsque tu �dites de l'XML, au moyen de nXML, tu disposes alors
d'une commande, li�e � la touche F12, qui alterne entre l'affichage et
l'effacement des tags.  Je ne sais pas si c'est exactement ce que tu
souhaites.

  Par exemple, les tags ne sont plus visibles, *et* ils ne
� remplissent plus l'espace � (c'est � dire qu'� la place, il n'y a
pas d'espaces).  Mais il y a moyen de faire en sorte que ce soit le
cas.

  Tu peux voir sur un petit exemple les deux �tats entre lesquels tu
alternes juste en pressant successivement F12 :

    <URL:http://www.fgeorges.org/tmp/nxml-mode-visible.png>
    <URL:http://www.fgeorges.org/tmp/nxml-mode-hided.png>

  Si tu es int�ress�, il ne te reste � plus qu'� � installer Emacs,
nXML, et utiliser le bout de code ci-dessus.

  Il y a ensuite toute sorte d'extensions possibles : n'agir que sur
une r�gion, que sur certains �l�ments (p.e. par nom, par regexp de
nom, par ...).

--drkm