🚀 go-pugleaf

In GNU Emacs 19.25.2 of Mon Aug  8 1994 on hpsrdpw (m68k-hp-hpux9)

In 'mh-e.el', in the function 'mh-get-new-mail' the variable 'mh-inc-prog'
is used in one branch of an 'if' but not used in the other branch.  Assuming
'mh-e.el' is part of the standard distribution, could you please make this
change there so it will be propagated appropriately?

The following is the corrected form of the function with the incorrect line
left in comments.

(defun mh-get-new-mail (maildrop-name)
  ;; Read new mail from a maildrop into the current buffer.
  ;; Return in the current buffer.
  (let ((point-before-inc (point))
	(folder mh-current-folder)
	(new-mail-p nil))
    (with-mh-folder-updating (t)
      (message (if maildrop-name
		   (format "inc %s -file %s..." folder maildrop-name)
		   (format "inc %s..." folder)))
      (setq mh-next-direction 'forward)
      (goto-char (point-max))
      (let ((start-of-inc (point)))
	(if maildrop-name
	    (mh-exec-cmd-output mh-inc-prog nil folder
				"-file" (expand-file-name maildrop-name)
				"-width" (window-width)
				"-truncate")
	    (mh-exec-cmd-output mh-inc-prog nil

;;; INCORRECT VERSION HARDWIRES 'inc'
;;;	    (mh-exec-cmd-output "inc" nil

				"-width" (window-width)))
	(message
	 (if maildrop-name
	     (format "inc %s -file %s...done" folder maildrop-name)
	     (format "inc %s...done" folder)))
	(goto-char start-of-inc)
	(cond ((looking-at "inc: no mail")
	       (message "No new mail%s%s" (if maildrop-name " in " "")
			(if maildrop-name maildrop-name "")))
	      ((re-search-forward "^inc:" nil t) ; Error messages
	       (error "inc error"))
	      (t
	       ;; remove old cur notation (cf mh-goto-cur-msg code)
	       (let ((cur-msg (car (mh-seq-to-msgs 'cur))))
		 (save-excursion
		   (and cur-msg
			(mh-goto-msg cur-msg t nil)
			(looking-at mh-cur-scan-msg-regexp)
			(mh-notate nil ?  mh-cmd-note))))
	       (setq new-mail-p t)))
	(keep-lines mh-valid-scan-line) ; Flush random scan lines
	(mh-delete-seq-locally 'cur)	; To pick up new one
	(setq mh-seq-list (mh-read-folder-sequences folder t))
	(mh-notate-user-sequences)
	(if new-mail-p
	    (progn
	      (mh-goto-cur-msg)
	      (mh-make-folder-mode-line))
	    (goto-char point-before-inc))))))