🚀 go-pugleaf

    From: kyle@uunet.uu.net (Kyle Jones)
    Subject: Re: Enabling a command forever - too easy

    ...
    
    I've pretty handy with Emacs and even I wouldn't mind having
    something like vi's "set report" facility so you would get a
    message if x number of lines are deleted.  This would be more
    useful than disabling the command outright.
    

Here something I wrote for a friend with the same wishes.  It
announces in the echo area when text has been cut or killed.  You
might want to enhance it further to only report if the character or
line count is above a certain threshhold.  And perhaps it should
print the number of lines spanned by the action.

 < Stephen
   MIT X Consortium


;;; feedback.el

;;; Kill region and save region, but with a message in the minibuffer
;;; telling you what happened.  Inspired by Eric Brosius.
;;; Written by Stephen Gildea <gildea@lcs.mit.edu> Sept 1988.

(defun save-region-with-feedback (beg end)
  "Save the region as if killed, but don't kill it.
Display a message saying what we have done."
  (interactive "r")
  (feedback-on-region "Saving region:" beg end)
  (copy-region-as-kill beg end))

(defun kill-region-with-feedback (beg end)
  "Kill between point and mark.
The text is deleted but saved in the kill ring.
Display a message saying what we have done."
  (interactive "r")
  (feedback-on-region "Killing region:" beg end)
  (kill-region beg end))
  
(defun feedback-on-region (msg beg end)
  (if (<= (- end beg) 50)
      (message "%s \"%s\"" msg
	       (string-visible-tabs (buffer-substring beg end)))
    (message "%s \"%s  ...  %s\"" msg
	     (string-visible-tabs (buffer-substring beg (+ beg 25)))
	     (string-visible-tabs (buffer-substring (- end 25) end)))))

(defun string-visible-tabs (string)
  "Returns a string identical to STRING except that all tab characters
have been replaced with the two characters \"^I\""
  (let ((new-string "") tab-pos)
    (while (setq tab-pos (string-match "\t" string))
      (setq new-string (concat new-string (substring string 0 tab-pos) "^I"))
      (setq string (substring string (match-end 0))))
    (concat new-string string)))

(global-set-key "\ew" 'save-region-with-feedback)
(global-set-key "\C-x\C-k" 'kill-region-with-feedback)