🚀 go-pugleaf

GNU Emacs 18.53.11 on NeXT 1.0.1

(Sorry, I hit C-c C-c too soon.)

I suggest how-many-region.  (Alternatively, how-many could take an
optional region, but this gets messy.)  This is useful in small online
Lisp programs, and interactively sometimes (although narrowing would
also work).

Here's the code.  The existing behavior (which I've preserved) doesn't
count zero-length matches.  Why not?

(defun how-many (regexp)
  "Print number of non-trivial matches for REGEXP following point."
  (interactive "sHow many matches for (regexp): ")
  (how-many-region (point) (point-max) regexp t))

(defun how-many-region (begin end regexp &optional interactive)
  "Print number of non-trivial matches for REGEXP in region.
Non-interactive arguments are Begin End Regexp"
  (interactive "r\nsHow many matches for (regexp): \np")
  (let ((count 0) opoint)
    (save-excursion
      (setq end (or end (point-max)))
      (goto-char (or begin (point)))
      (while (and (< (setq opoint (point)) end)
		  (re-search-forward regexp end t))
	(if (= opoint (point))
	    (forward-char 1)
	  (setq count (1+ count))))
      (if interactive (message "%d occurrences" count))
      count)))