🚀 go-pugleaf

With emacs 18.55.9 the mail notification no longer works correctly if
your mail reader drains the spool file without deleting it (e.g. MH's
inc command).

The follwing version of display-time-filter in time.el will fix it.

(defun display-time-filter (proc string)
  (let ((time (current-time-string))
	(load (format "%03d" (car (load-average))))
	(mail-spool-file (concat rmail-spool-directory
				 (or (getenv "LOGNAME")
				     (getenv "USER")
				     (user-login-name))))
	hour pm)
    (setq hour (read (substring time 11 13)))
    (setq pm (>= hour 12))
    (if (> hour 12)
	(setq hour (- hour 12))
      (if (= hour 0)
	  (setq hour 12)))
    (setq display-time-string
	  (concat (format "%d" hour) (substring time 13 16)
		  (if pm "pm " "am ")
		  (substring load 0 -2) "." (substring load -2)
		  (if (and (file-exists-p mail-spool-file)
			   ;; file not empty?
			   (> (nth 7 (file-attributes mail-spool-file)) 0))
		      " Mail"
		      "")))
    ;; Append the date if desired.
    (if display-time-day-and-date
	(setq display-time-string
	      (concat (substring time 0 11) display-time-string))))
  ;; Force redisplay of all buffers' mode lines to be considered.
  (save-excursion (set-buffer (other-buffer)))
  (set-buffer-modified-p (buffer-modified-p))
  ;; Do redisplay right now, if no input pending.
  (sit-for 0))