🚀 go-pugleaf

  If running a subshell the output of a shell command is often displayed
  with the last line in the middle of the Emacs window. I'd rather like
  Emacs to put the shell prompt always at the bottom of the window.

This requires writing an elisp filter function for the shell process.
(I think you also have to set `scroll-step' to 2 or some value that will
work.)  Here's the code I wrote up some time ago:

  (defun my-shell-filter (process string)
    (let* ((buffer (process-buffer process))
	   (marker (process-mark process))
	   (window (get-buffer-window buffer))
	   (current-window (selected-window)))
      (save-excursion
	(set-buffer buffer)
	(goto-char marker)
	(insert string)
	(set-marker marker (point)))
      (if window
	  (unwind-protect
	      (progn
		(select-window window)
		(goto-char marker)
		(recenter (- (window-height) 2))
		(end-of-line))
	    (select-window current-window)))))

  (defun my-shell ()
    (interactive)
    (shell)
    (set-process-filter (get-process "shell") 'my-shell-filter))

Just start up the shell with M-x my-shell.  You may also, as I said,
have to M-x set-variable scroll-step. 

--
Raul Acevedo
acevedo@athena.mit.edu

"Remember, Information is not knowledge; Knowledge is not Wisdom;
Wisdom is not truth; Truth is not beauty; Beauty is not love;
Love is not music; Music is the best."
	 - Frank Zappa