🚀 go-pugleaf

>>> On 3 Apr 91 05:44:44 GMT,
>>> "David" == grabiner@math.harvard.edu (David Grabiner) writes:

David> I have a mail-setup-hook which already creates a Full-Name field in any
David> mail I send out.  When I use the current version of VM (5.31), it adds
David> another Full-Name field, which I don't want.  I would like to have a
David> variable to set in my .vm file to inhibit the creation of the Full-Name
David> field.

David> Deleting the Full-Name field from my mail-setup-hook is not a solution,
David> because I often send mail from outside VM as well.

    You want something to add the extra header only if it doesn't exist,
  right?  I use a couple of general functions for this purpose:

  +--- add/remove headers ---
  |
  | (defun mail-add-header (HEADER CONTENTS &optional REPLACE)
  |   "Add the specified HEADER to the current mail message, with the given 
  | CONTENTS.  
  | If the header already exists, the contents are left unchanged, unless optional 
  | argument REPLACE is non-nil."
  |   (save-excursion
  |     (let ((header-exists (mail-position-on-field HEADER)))
  |       ;; Delete old contents if REPLACE is set
  |       (if (and header-exists REPLACE)
  | 	  (let ((end (point))
  | 		(beg (progn
  | 		       (re-search-backward (concat HEADER ": "))
  | 		       (goto-char (match-end 0)))))
  | 	    (delete-region beg end)))
  |       ;; Add new contents if REPLACE is set, or this is a new header.
  |       (if (or (not header-exists) REPLACE)
  | 	  (progn (insert CONTENTS) CONTENTS)))))
  | 
  | (defun mail-remove-header (HEADER)
  |   "Remove the specified HEADER from the current mail message."
  |   (save-excursion
  |     (if (mail-position-on-field HEADER 'soft)
  | 	(let ((end (point))
  | 	      (beg (progn
  | 		     (re-search-backward (concat HEADER ": "))
  | 		     (goto-char (match-beginning 0)))))
  | 	  (delete-region beg (1+ end))))))
  |     

    If you want make sure that one (and only one) "Full-Name" field gets
  added to all your mail, do something like:

  (setq mail-setup-hook
    '(lambda ()
        (mail-add-header "Full-Name" (user-full-name))
        ;; ... and the rest ...
        ))

  And for those of you who are bugged by the header:

  (setq mail-setup-hook
    '(lambda ()
        (mail-remove-header "Full-Name")
        ;; ... and the rest ...
        ))

  ... I know that this is overkill for just adding the Full-Name header,
  but you never know when the more general function might be useful :-)

--
    /-------------------- mike-w@cs.aukuni.ac.nz ---------------------\
    | Mike Williams, Computer Science, Auckland University, Aotearoa. |
    \-------------- What's another word for Thesaurus? ---------------/
-- 
New administrater uofa.