🚀 go-pugleaf

What I really want is a bit of elisp so that help windows (ie when you
type M-x apropos mail) come up in seperate screens.

Have people tried to enforce a one screen / one window policy on
epoch, by replacing the new window lisp code with new screen lisp
code? I think there'd be problems, but it might be feasible. This
would be a general solution, although possibly too extreme.
                __
nelson@reed.edu \/   You're free, so anything could happen, so happy birthday

In article <1992Nov17.230847.23183@reed.edu>, nelson@reed.edu (Nelson Minar) writes:

> What I really want is a bit of elisp so that help windows (ie when you
> type M-x apropos mail) come up in seperate screens.

Here's one of the first pieces of Epoch code I wrote.  It even tries
to get the window that it pops up not to overlap with your current
one, though admittedly it doesn't try all _that_ hard.  I require it
in my .emacs if I'm running Epoch, though I suppose that a better way
to do things would just to set the temp-buffer-show-hook in my .emacs
and autoload this when I call check-help-screen-buffer.  Type 'q' to
get out of the screen that it pops up.

david carlton
carlton@husc.harvard.edu

;; Help commands for Epoch.
;;
;; These commands cause help to create a new screen each time it is
;; run, rather than merely a new buffer.
;;
;; by david carlton, carlton@husc.harvard.edu

(provide 'epoch-help)

(defvar help-return-screen nil)		; used to return to the old screen
(defvar help-screen-mode-hooks nil)
(defvar help-screen-mode-map nil)
(defvar help-screen-cursor-glyph 92)	; question-arrow
(defvar help-screen-dimensions "80x24")
(defvar help-screen-xpos 10)
(defvar help-screen-ypos 100)

(defun check-help-screen-buffer (buffer)
  (if (string-equal (buffer-name buffer) "*Help*")
      (create-help-screen buffer)
    (display-buffer buffer)))

(defun create-help-screen (buffer)
  (set-buffer buffer)
  (help-screen-mode)
  (let
      ((help-screen
	(create-screen buffer (get-help-screen-alist))))
    (setq help-return-screen (current-screen))
    (map-screen help-screen)
    (select-screen help-screen)
    (cursor-to-screen (current-screen))))

(defun get-help-screen-alist ()
  (cons (cons 'geometry (get-help-screen-geometry))
	(list (cons 'cursor-glyph help-screen-cursor-glyph))))

(defun get-help-screen-geometry ()
  (let ((screen-dims (screen-information)))
    (concat help-screen-dimensions
	    (if (< (car screen-dims) (- (caddr screen-dims) help-screen-xpos))
		"-"
	      "+")
	    help-screen-xpos
	    "+"
	    help-screen-ypos)))

(defun help-screen-mode ()
  "Mode for help screen created by Epoch"
  (interactive)
  (kill-all-local-variables)
  (use-local-map help-screen-mode-map)
  (setq major-mode 'help-screen-mode)
  (setq mode-name "help-screen")
  (run-hooks 'help-screen-mode-hooks))

(defun create-help-screen-mode-map (keymap)
  (suppress-keymap keymap)
  (define-key keymap "q" 'exit-help-screen-mode)
  (define-key keymap " " 'scroll-up)
  (define-key keymap "\177" 'scroll-down)
  (define-key keymap "s" 'isearch-forward)
  keymap)

(defun exit-help-screen-mode ()
  "Deletes help screen, leaves help-screen-mode"
  (interactive)
  (delete-screen)
  (select-screen help-return-screen)
  (cursor-to-screen help-return-screen))


(defun print-help-return-message (&optional function)
  "Prints help-return-message for help-screen"
  (and (not (get-buffer-window standard-output))
       (funcall (or function 'message)
		"Type q to remove help screen."))) ; should be using
					           ; substitute-command-keys

(if (not help-screen-mode-map)
    (setq help-screen-mode-map
	  (create-help-screen-mode-map (make-keymap))))

(setq temp-buffer-show-hook 'check-help-screen-buffer)

scotth@oldman.com (Scott Herzinger) writes:

>I've recently started using Epoch 4.2. I'm in search of Epoch goodies
>that augment conventional Emacs functionality that I use often. Are
>there any recommended packages?

Ditto.

>At the moment, I'd particularly like things like name completion and
>M-x compile/grep to pop up screens instead of Emacs windows.  I've
>seen the Epoch-specific elisp descriptions in the FAQ, and didn't see
>anything specifically mentioned that addresses this functionality.

Yes, the same thing occurred to me.  What I'd like is for just about
everything that currently splits a screen into multiple windows to instead
create new X windows of appropriate size.  Plus of course new ones could
be created that would overlap or go someplace else or whatever.  

The real reason I want this is because it seems that if I try to make a
particular buffer have its own background color, this causes only the
places where characters are displayed to have that background.  So I might
have

	yyyyyyyyyyyybbbbbbbbbbb
	yyyyyyyyyyyyyyyybbbbbbb
	yyyyyybbbbbbbbbbbbbbbbb
	bbbbbbbbbbbbbbbbbbbbbbb

Where "y" and "b" stand for two different background colors.

If I make the buffer have its own screen I can set the background for
the whole screen, which works quite nicely.  

Anyway, if anyone has a fix for epoch 4.2 for the background styles,
or a way to define window-related operations to deal with screens 
instead, please post or send me a copy as well as the first author.


-- 
Fred Douglis
Matsushita Information Technology Laboratory  | Email: douglis@mitl.com
182 Nassau Street			      | Phone: +1 609 497-4600
Princeton, NJ 08542 USA 		      | Fax:   +1 609 497-4013