🚀 go-pugleaf

Hi Adrian,
Een tijdje geleden maakte ik een programmaatje in Assembler dat het
ATX-systeem uitschakelt.

Misschien helpt onderstaande code je op weg.
Tot ziens, Eric

		TITLE	ATXSLEEP.ASM

;Brings ATX motherboard in sleep condition

;MASM 6.1A used ML /AT ATXSLEEP.ASM

;------------------------------------------------------------------------------
CODE            SEGMENT	'CODE'
		ASSUME	DS:CODE,SS:CODE
                ORG     0100H			;Code loaded at offset 0100H
		.RADIX	10H			;Default all HEX
;;		.386				;80386 and up

MAIN		PROC	FAR
		MOV	AX,5301			;Connect Real Mode Interface
		XOR	BX,BX			;Device ID system Bios
		INT	15
		JC	AMPFAIL
		
		MOV	AX,530E			;Driver version
		XOR	BX,BX			;Device ID system Bios
		MOV	CX,0102			;APM 1.2
		INT	15
		JC	AMPFAIL
		
		MOV	AX,5307			;Suspend System
		MOV	BX,0001			;Device ID all pwr managed dev.
		MOV	CX,0003			;System off
		INT	15
		JNC	DOS_EXIT

AMPFAIL:	MOV	DX,OFFSET FAIL_MESS
		
;Print message DS:DX
MESS_EXIT:	CALL	PRT_STR

;Terminate program		
DOS_EXIT:	MOV	AX,4C00
		INT	21
MAIN		ENDP
;------------------------------------------------------------------------------
;Print $ terminated message DS:DX
PRT_STR		PROC	NEAR
		MOV	AH,09			;Print string
		INT	21			;DOS
		RET
PRT_STR		ENDP

FAIL_MESS	DB	0A,0D,"APM fail$"

CODE            ENDS
                END     MAIN

--

Eric P. van Westendorp  Tel: +31(0252)210579
Reigerslaan 22  2215NN Voorhout  Netherlands

Arian Haeser wrote:
> 
> hi all :))
> 
> Weet iemand de code om een ATX-systeem uit te schakelen??
> 
> Arian Haeser