🚀 go-pugleaf

    Hallo all!

Ok, ich hab die Loesung!

dip -v ist fuer sowas recht hilfreich, nur sollte man auch die
Bildschirmausgaben WIRKLICH lesen.

get $locip remote funktionierte, nur beim nachfolgenden 

print Connected to $remote under IP $locip.

hats ihn mit 

Unknown variable locip.

aufgestellt.

Und? Auch dreitausendmal hingeschaut und nix gefunden? Tja, der bloede Punkt
war's! Den darf man naemlich nicht direkt an das $locip dranklatschen, denn
sonst sucht er die Variable "$locip.", die's natuerlich nicht gibt - was er
auch in der Fehlermeldung schreibt - nur hab ich den Punkt dort natuerlich fuer
das Satzende der Fehlermeldung gehalten....$%&!?"#

Ok, zur Belohnung gibts fuer alle jetzt ein schoenes dip-script, mit dem man
den stud1 anwaehlen kann; mit BUSY-redial und es probiert auch alle 3
Nummernserien aus.

=====================================stud1.dip============================

# dip script for stud1.tuwien.ac.at
# by Martina Umlauft, after 2 days of screaming and cursing. ;-)

get $remote stud1.tuwien.ac.at

port modem
speed 38400
modem HAYES
reset
flush

send ATZ\r
wait OK 2
if $errlvl != 0 goto error

dial:
# 1. Nummernserie

  send ATs30=0s38=8s11=80s95=43sc0=0sc1=0sc2=067sc4=13sc5=0sc6=67sc7=0sc8=4\r
# dieser Mega-Initstring ist fuer das Supra V.34 (zur BUSY-Erkennung),
# bitte an's eigene Modem anpassen

  wait OK 2
  if $errlvl != 0 goto error
  send ATDT5874692\r
  wait BUSY 20
if $errlvl != 0 goto not_busy
  print 1. Nummernserie BUSY.

# 2. Nummernserie
  send ATs30=0s38=8s11=80s95=43sc0=0sc1=0sc2=067sc4=13sc5=0sc6=67sc7=0sc8=4\r
  wait OK 2
  if $errlvl != 0 goto error
  send ATDT5874695\r
  wait BUSY 20
if $errlvl != 0 goto not_busy
  print 2. Nummernserie BUSY.

# 3. Nummernserie
  send ATs30=0s38=8s11=80s95=43sc0=0sc1=0sc2=067sc4=13sc5=0sc6=67sc7=0sc8=4\r
  wait OK 2
  if $errlvl != 0 goto error
  send ATDT5867578\r
  wait BUSY 20
if $errlvl != 0 goto not_busy
  print 3. Nummernserie BUSY.

#alle Nummernserien BUSY, erneuter Versuch in einer Minute
  sleep 60
goto dial

not_busy:
  wait CONNECT 40
  if $errlvl != 0 goto error

sleep 3
wait Username: 3
if $errlvl != 0 goto error
send e<MatrikelNr>@stud1.tuwien.ac.at\n

wait Password: 1
if $errlvl != 0 goto error
send <password>\n

sleep 3
send slip\n

wait Your 3
wait IP 1
wait address 1
wait is 1
get $locip remote 30

print Connected to $remote , $rmtip under IP $locip .
default
mode SLIP
goto exit

error:
 print SLIP to $remote failed.

exit:

=====================================stud1.dip============================

Die IP Adr. von stud1 muss entweder in /etc/hosts stehen oder sonstwie fuer den
Rechner aufzuloesen sein (Nameserver,...), oder man gibt sie direkt an (stud1 =
128.130.35.37). Weiters ist es wichtig, dass man unbedingt zumindest auf "IP
address is" wartet, denn die Intelligenzler vom EDVZ haben genau in der Zeile
drueber "Async interface address is unnumbered" geschrieben; dh nur mit warten
auf "address is" geht's nicht. Achja, /dev/modem muss natuerlich auf die
richtige Schnittstelle /dev/cua# zeigen, sonst muss man bei port die richtige
cua eintragen.

Ok, vielleicht freut sich ja wer drueber.

Jetzt muss ich nur noch hinkriegen, dass ich bei bestehender Verbindung auch
vom anderen LAN-Rechner zum stud1 komme - any hints? Mit telnet auf den
SLIP-Rechner und dann von dort kann ja jeder. Und Nameserver will ich auch
keinen aufsetzen.

 
    Bye,
        /|/|artina :)