🚀 go-pugleaf

On Wed, 24 Jun 1992 18:51:00 PDT Ed Rovera said:
> .
> .
> .
>                                                        If the user
>wants to have his machine wait only 45 minutes -- for whatever reason
>-- he doesn't have the option.  I'm in complete agreement that the
>REMINDER statement constitutes the default timeout but my client is of
>the opinion that making his machine wait 60 minutes when he'd rather
>it enter an error routine sooner is a bit Draconian and I see his
>point.

   Well, until Systems Center provides a way to override the site
default, your client will have to do something like the following
(which takes advantage of the NOWAIT option for VMTAPE MOUNT):

/* REXX, of course! */
Address Command
Parse Upper Arg volser params '(' options ')' .
/* Add code to process parameters (vaddr, DSN) & options (READ, WRITE, etc) */
'VMTAPE MOUNT' volser vaddr <dsn> '(NOWAIT' <options> ')'
Say "Mount request for tape" volser "has been issued...please wait..."
Say "(Press the ENTER key to stop waiting and cancel the request)"
wait_mins = 10  /* Max time to wait for tape, should be a parameter w/default*/
wait_secs = wait_mins * 60
trip_count = wait_secs / 10  /* Assuming delay of 10 secs between checks */
'MAKEBUF'
bufnum = rc
Do trip_count  /* Loop, waiting for tape to be attached */
  'WAKEUP +00:00:10 (CONS NOREAD QUIET'  /* Wait 10 secs or for ENTER key */
  /* WAKEUP comes with the IPF product.  Can use CP SLEEP instead, but may */
  /* have to give up ability to interrupt with ENTER key. */
  retcd = rc
  If retcd = 6 Then Signal EndIt  /* User pressed ENTER key, exit */
  'EXECIO * CP (STRING CP QUERY VIRTUAL' vaddr
  Pull resp
  Parse Var resp With 'TAPE' . 'ON ' devtype raddr
  If devtype = 'TAPE' Then Signal GotIt  /* Tape is attached */
End  /* of loop */
'DROPBUF' bufnum
Say
Say "Maximum wait period was reached, tape has not been attached."
Say
Exit 12
GotIt:  /* Tape is attached */
'DROPBUF' bufnum
Say
Say "Tape" volser "is attached at address" vaddr"."
Say
Exit
EndIt:  /* User got tired of waiting, cancel request */
'DROPBUF' bufnum
'VMTAPE CANCEL' vaddr
Say
Say "Mount request for tape" volser "has been canceled."
Say
Exit 12