🚀 go-pugleaf

"Dennis Cote" <denniscote@gmail.com> wrote in message 
news:480632fb$1@newsgroups.borland.com...

> I am now testing the application under Vista. It does not
> work under Vista and I believe the issue has to do with
> Administrator rights

You are using the TIdICMPClient component, which uses a RAW socket 
internally (as opposed to using a TCP or UDP socket).  Admin rights are 
required in order to use RAW sockets on NT4 onwards (which means your code 
should not have worked on XP, either, unless you are running as an admin). 
Of course, Microsoft circumvents its own rules by allowing icmp.dll to use 
RAW sockets without admin rights.

> I think some type casting must be needed to tell the
> compiler not to check the range of the result before
> passing it to CheckForSocketError() but I'm not
> sure how that is done in Delphi.

Rather than casting, you could disable range checking itself for 
NewSocketHandle().  Indy does this in a couple of other places, for example:

    function TIdStackBSDBase.NewSocketHandle(const ASocketType: 
TIdSocketType;
        const AProtocol: TIdSocketProtocol;
        const AIPVersion: TIdIPVersion = ID_DEFAULT_IP_VERSION;
        const AOverlapped: Boolean = False): TIdStackSocketHandle;
    begin
        {$IFOPT R+}
        {$DEFINE RestoreRangeCheckingON}
        {$R-}
        {$ENDIF}
        Result := CheckForSocketError(WSSocket(IdIPFamily[AIPVersion], 
ASocketType, AProtocol, AOverlapped));
        {$IFDEF RestoreRangeCheckingON}
        {$R+}
        {$UNDEF RestoreRangeCheckingON}
        {$ENDIF}
    end;

Otherwise, you would have to hard-code the casting, which can be pretty 
ugly:

    function TIdStackBSDBase.NewSocketHandle(const ASocketType: 
TIdSocketType;
        const AProtocol: TIdSocketProtocol;
        const AIPVersion: TIdIPVersion = ID_DEFAULT_IP_VERSION;
        const AOverlapped: Boolean = False): TIdStackSocketHandle;
    begin
        Result := 
TIdStackSocketHandle(CheckForSocketError(Integer(WSSocket(IdIPFamily[AIPVersion], 
ASocketType, AProtocol, AOverlapped))));
    end;

Here is a cleaner version:

    function TIdStackBSDBase.NewSocketHandle(const ASocketType: 
TIdSocketType;
        const AProtocol: TIdSocketProtocol;
        const AIPVersion: TIdIPVersion = ID_DEFAULT_IP_VERSION;
        const AOverlapped: Boolean = False): TIdStackSocketHandle;
    begin
        Result := WSSocket(IdIPFamily[AIPVersion], ASocketType, AProtocol, 
AOverlapped);
        CheckForSocketError(Integer(Result));
    end;

> I also suspect this same error may exist in other places in the code.

Actually, it doesn't.  Everywhere else that calls CheckForSocketError() 
passes it an Integer.

> Can anyone say if this analysis is correct, and if so how the
> result should be cast from unsigned to signed without the
> range check?

Since CheckForSocketError() is expecting an Integer error code, not a 
TSocket handle, I would suggest changing TIdStackBSDBase.NewSocketHandle() 
to the following instead:

    function TIdStackBSDBase.NewSocketHandle(const ASocketType: 
TIdSocketType;
        const AProtocol: TIdSocketProtocol;
        const AIPVersion: TIdIPVersion = ID_DEFAULT_IP_VERSION;
        const AOverlapped: Boolean = False): TIdStackSocketHandle;
    begin
        Result := WSSocket(IdIPFamily[AIPVersion], ASocketType, AProtocol, 
AOverlapped);
        if Result = Id_INVALID_SOCKET then begin
            RaiseLastSocketError;
        end;
    end;


Gambit 

Remy Lebeau (TeamB) wrote:
> 
> You are using the TIdICMPClient component, which uses a RAW socket 
> internally (as opposed to using a TCP or UDP socket).  Admin rights are 
> required in order to use RAW sockets on NT4 onwards (which means your code 
> should not have worked on XP, either, unless you are running as an admin). 
> Of course, Microsoft circumvents its own rules by allowing icmp.dll to use 
> RAW sockets without admin rights.
> 

Yes, I am running as an administrator under XP and Vista.

> 
> Rather than casting, you could disable range checking itself for 
> NewSocketHandle().  Indy does this in a couple of other places, for example:
> 
>     function TIdStackBSDBase.NewSocketHandle(const ASocketType: 
> TIdSocketType;
>         const AProtocol: TIdSocketProtocol;
>         const AIPVersion: TIdIPVersion = ID_DEFAULT_IP_VERSION;
>         const AOverlapped: Boolean = False): TIdStackSocketHandle;
>     begin
>         {$IFOPT R+}
>         {$DEFINE RestoreRangeCheckingON}
>         {$R-}
>         {$ENDIF}
>         Result := CheckForSocketError(WSSocket(IdIPFamily[AIPVersion], 
> ASocketType, AProtocol, AOverlapped));
>         {$IFDEF RestoreRangeCheckingON}
>         {$R+}
>         {$UNDEF RestoreRangeCheckingON}
>         {$ENDIF}
>     end;
> 

This would also disable the other range check done during the call of 
WSSocket(). I'm don't think that is needed, and it should probably be 
left until it is known to cause a problem.

> 
>> I also suspect this same error may exist in other places in the code.
> 
> Actually, it doesn't.  Everywhere else that calls CheckForSocketError() 
> passes it an Integer.
> 

Good to hear.

> 
> Since CheckForSocketError() is expecting an Integer error code, not a 
> TSocket handle, I would suggest changing TIdStackBSDBase.NewSocketHandle() 
> to the following instead:
> 
>     function TIdStackBSDBase.NewSocketHandle(const ASocketType: 
> TIdSocketType;
>         const AProtocol: TIdSocketProtocol;
>         const AIPVersion: TIdIPVersion = ID_DEFAULT_IP_VERSION;
>         const AOverlapped: Boolean = False): TIdStackSocketHandle;
>     begin
>         Result := WSSocket(IdIPFamily[AIPVersion], ASocketType, AProtocol, 
> AOverlapped);
>         if Result = Id_INVALID_SOCKET then begin
>             RaiseLastSocketError;
>         end;
>     end;
> 

Thanks Remy. I will make this change in my local source file. Will this 
also be changed in the Indy SVN source, or will I have to apply a patch 
to future downloads?

Dennis Cote

"Dennis Cote" <denniscote@gmail.com> wrote in message 
news:480668fa$1@newsgroups.borland.com...

> Thanks Remy. I will make this change in my local source file.
> Will this also be changed in the Indy SVN source, or will I
> have to apply a patch to future downloads?

If it works for you, then I will merge it into SVN.


Gambit 

Remy Lebeau (TeamB) wrote:
> 
> If it works for you, then I will merge it into SVN.
> 

It works for me.

I get correct operation of the ICMP client under XP.

I also now get an Access Denied exception under Vista (as expected) 
rather than the Range Error exception when WSSocket() fails.

Dennis Cote