🚀 go-pugleaf

In article <3dddd294$1@newsgroups.borland.com>, Gerke Preussner wrote:
> I used Delphi 5 for quite a long time and successfully implemented
> plugin-based programs in the past. I'm currently migrating to Delphi 7 and
> trying to write a small generic plugin system. Unfortunately, i have
> difficulties getting it to work properly.
> 
> Basically, the main program contains a control that will look for DLLs in
> the program folder and load them as plugins. The DLLs contain forms which
> will then be opened by the main program on demand. Loading the DLLs doesn't
> work and the LoadLibrary() function stops with the following exception:
> 
>    "Cannot create application object in shared object or library"

You have managed somehow to create a CLX DLL project. I just did a quick test 
with D7 and it works without any problems in a VCL project.

library TestDLL;

uses
  SysUtils,
  Classes,
  DLLUnit2 in 'DLLUnit2.pas' {Form2};

{$R *.res}
exports
  CreateDLLForm;

begin
end.

unit DLLUnit2;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs;

type
  TForm2 = class(TForm)
  private
    { Private declarations }
  public
    { Public declarations }
  end;

Procedure CreateDLLForm;

implementation

{$R *.dfm}
Procedure CreateDLLForm;
  Begin
    With TForm2.Create(Application) Do
    try
      ShowModal
    finally
      free
    end;
  End;

end.

Testroutine in host app:

procedure TForm1.Button1Click(Sender: TObject);
var
  hLib: THandle;
  proc: Procedure;
begin
  hLib:= LoadLibrary( 'testdll.dll');
  if hLib <> 0 Then begin
    @proc := GetProcAddress( hLib, 'CreateDLLForm' );
    If Assigned( proc ) Then
      proc;
  end;
end;

--
Peter Below (TeamB)  
Use the newsgroup archives :
http://www.mers.com/searchsite.html
http://www.tamaracka.com/search.htm
http://groups.google.com
http://www.prolix.be