🚀 go-pugleaf

In article <3dddd997$1@newsgroups.borland.com>, Grega Loboda wrote:
> I know I've done this before, but...lost it. I want to show a status form.
> It should be shown modal. When form is on the screen, I would like to do
> something, after that, close it. How?

Here is a fragment from a form class i use for this kind of task. The 
relevant parts are the constructor and destructor. YOu would use this like

  with TPseudomodalWaitform.Create( self, aMessage ) do
  try
    DoTheLengthyTask
  finally
    Free
  end;  
  
{== PseudomodalWaitformU ==============================================}
{: This form can be used to display a wait message while some processing
   is ongoing.
@author Dr. Peter Below
@desc   Version 1.0 created 1 Februar 2002<BR>
        Current revision 1.0<BR>
        Last modified       1 Februar 2002<P>
The form will automatically center over the passed owner form and
adjust in size to the passed message. It will show itself when created
and disable all other forms of the application. The form cannot be
closed by the user.  }
{======================================================================}
{$BOOLEVAL OFF}{Unit depends on shortcut boolean evaluation}
Unit PseudomodalWaitformU;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  ExtCtrls, Expanel;

type
  TPseudomodalWaitform = class(TForm)
    ExPanel1: TExPanel;
    PaintBox: TPaintBox;
    procedure PaintBoxPaint(Sender: TObject);
    procedure FormCloseQuery(Sender: TObject; var CanClose: Boolean);
  private
    FMessage: String;
    FOwner  : TForm;
    FWindowlist: Pointer;
    Procedure MeasureMessage;
    procedure SetMessage(const Value: String);
  public
    Constructor Create( aOwner: TForm; const aMsg: String ); reintroduce;
    Destructor Destroy; override;
    property Message: String read FMessage write SetMessage;
  end;

Implementation

Uses UIHelpers, Styles;

{$R *.DFM}

Constructor TPseudomodalWaitform.Create(aOwner: TForm; const aMsg: String);
  Begin
    If not Assigned( aOwner ) Then
      aOwner := Screen.ActiveForm;
    Assert( Assigned( aOwner ),
            'TPseudomodalWaitform.Create: aOwner cannot be nil!');

    inherited Create( nil );
    FOwner   := aOwner;
    FMessage := aMsg;
    HandleNeeded;
    MeasureMessage;
    Paintbox.Color := Styles.Readonlycolor;
    Show;
    Update;
    Fwindowlist := DisableTaskWindows( handle );
  End;

Destructor TPseudomodalWaitform.Destroy;
  Begin
    OnCloseQuery := Nil;
    If Assigned( FWindowlist ) Then
      EnableTaskWindows( FWindowlist );
    If Assigned( FOwner ) Then
      FOwner.Show;  
    inherited;
  End;

procedure TPseudomodalWaitform.FormCloseQuery(Sender: TObject;
  var CanClose: Boolean);
begin
  CanClose := False;
end;

  
  
--
Peter Below (TeamB)  
Use the newsgroup archives :
http://www.mers.com/searchsite.html
http://www.tamaracka.com/search.htm
http://groups.google.com
http://www.prolix.be