🚀 go-pugleaf

In both versions 3.2 and 4.0 of Epoch the definition of
normal-top-level in startup.el seems buggy, although it may be
difficult to trigger the bug.  The problem is that only the first form
is protected by an unwind-protect.  The following should be changed
from:

(defun normal-top-level ()
  (if command-line-processed
      (message "Back to top level.")
    (setq command-line-processed t)
    ;; In presence of symlinks, switch to cleaner form of default directory.
    (if (and (not (eq system-type 'vax-vms))
	     (getenv "PWD"))
	(setq default-directory (file-name-as-directory (getenv "PWD"))))
    (unwind-protect
      (if (boundp 'epoch::version)
	(run-hooks 'epoch-setup-hook)
      )
	(command-line)
      (and term-setup-hook
	   (funcall term-setup-hook))
      (and window-setup-hook
	   (funcall window-setup-hook)))))

to:

(defun normal-top-level ()
  (if command-line-processed
      (message "Back to top level.")
    (setq command-line-processed t)
    ;; In presence of symlinks, switch to cleaner form of default directory.
    (if (and (not (eq system-type 'vax-vms))
	     (getenv "PWD"))
	(setq default-directory (file-name-as-directory (getenv "PWD"))))
    (unwind-protect
	(progn
	  (if (boundp 'epoch::version)
	      (run-hooks 'epoch-setup-hook))
	  (command-line))
      (and term-setup-hook
	   (funcall term-setup-hook))
      (and window-setup-hook
	   (funcall window-setup-hook)))))

Note the PROGN that encloses the calls to epoch-setup-hook and
command-line.

--
Martin Boyer                            mboyer@ireq-robot.hydro.qc.ca
Institut de recherche d'Hydro-Quebec    mboyer@ireq-robot.uucp
Varennes, QC, Canada   J3X 1S1
+1 514 652-8412